//#include "UILib.cs"
//#include "Pong.cs"

int uiRoot, uiBackground, uiScroll, uiScroll2;
int uiReceiveGameWorld;
int uiSpectatorMenu, uiInGamePlayers;
int uiFollowMenu;
int uiGameOver, uiStageClear, uiStageClearList, g_StageClearSelection;
int uiUnlock;
int uiNetRoundOver, uiNetGameOver, uiRoundScoreboard, uiRoundScoreListTitle, uiRoundScoreList, uiCompetitionHostWin;
int uiFinalScoreboard, uiFinalScoreList;
int uiAutoDemo, uiCredit, uiDedicatedServer;
int uiStartMenu, uiStartList;
int uiInGameScoreboard, uiInGameScoreList;
int uiMissionObjective, uiMissionObjectiveList;
int uiTrainingMenu, uiTrainingList, uiTrainingOver1, uiTrainingOver2;
int uiConfirmLeaveGame, uiConfirmJoinOtherGame, uiSessionNotCompatible;
int uiSettingMenu, uiSettingList, g_settingSelection;
int uiMusicVolumeOption, uiEffectsVolumeOption, uiVoiceVolumeOption;
int uiVideoGammaOption, uiVideoBrightnessOption, uiVideoContrastOption;
int uiControllerVibrationOption, uiCameraInvertOption;
int uiShowPlayerName;
int uiSettingLiveMenu, uiSettingLiveList, g_settingLiveSelection, uiAppearOfflineOption, uiVoiceThroughSpeaker, uiVoiceSpeakerVolume;
int uiComboTable, uiComboList;
int uiKickMenu, uiKickList, g_kickSelection, g_kickPlayerID, uiConfirmKick;
int uiPong;
int uiLoginState2;
int iconDead, iconVIP, iconFriendRequest, iconGameInvite;
int g_lastActiveUI = 0;

void ShowPage(int id, int bkg)
{
	Activate(uiRoot, 1);
	RenderWorld(1);

	if (bkg==0 && GetAppState()==APPSTATE_GAME_OVER)		// gameover, dark screen
		bkg = 1;

	int bkgShow;
	Begin(uiBackground); bkgShow=IsShow(); End();
	Activate(uiBackground, bkg);
	if (bkg)
	{
		Begin(uiBackground);
			if (bkg == 2)
				Color(0,0,0,1);		// scenario stage clear, full dart background
			else
			{
				if (bkgShow)
					Color(0,0,0,0.8);	// dark background already exist
				else
					TweenColor(0,0,0,0, 0,0,0,0.8, 0.5);	// fadeout
			}
		End();
	}

	Activate(uiSpectatorMenu, id==uiSpectatorMenu);
	Activate(uiFollowMenu, id==uiFollowMenu);
	Activate(uiReceiveGameWorld, id==uiReceiveGameWorld);
	Activate(uiStageClear, id==uiStageClear);
	Activate(uiGameOver, id==uiGameOver);
	Activate(uiNetRoundOver, id==uiNetRoundOver);
	Activate(uiNetGameOver, id==uiNetGameOver);
	Activate(uiCompetitionHostWin, id==uiCompetitionHostWin);
	Activate(uiTrainingMenu, id==uiTrainingMenu);
	Activate(uiTrainingOver1, id==uiTrainingOver1);
	Activate(uiTrainingOver2, id==uiTrainingOver2);
	Activate(uiPong, id==uiPong);
	Activate(uiStartMenu, id==uiStartMenu);
	Activate(uiAutoDemo, id==uiAutoDemo);
	Activate(uiCredit, id==uiCredit);
	Activate(uiDedicatedServer, id==uiDedicatedServer);
	Activate(uiInGameScoreboard, id==uiInGameScoreboard);
	Activate(uiMissionObjective, id==uiMissionObjective);
	Activate(uiConfirmLeaveGame, id==uiConfirmLeaveGame);
	Activate(uiConfirmJoinOtherGame, id==uiConfirmJoinOtherGame);
	Activate(uiSessionNotCompatible, id==uiSessionNotCompatible);
	Activate(uiSettingMenu, id==uiSettingMenu);
	Activate(uiSettingLiveMenu, id==uiSettingLiveMenu);
	Activate(uiComboTable, id==uiComboTable);
	Activate(uiKickMenu, id==uiKickMenu);
	Activate(uiConfirmKick, id==uiConfirmKick);
	Activate(uiUnlock, id==uiUnlock);

	PlayUIAnimation(id, 0);
}


void OnActivate(int a)
{
//	var_fps = 50;
	g_lastActiveUI = GetActiveUI();

	Activate(uiRoundScoreboard, 0);
	Activate(uiFinalScoreboard, 0);
	ShowScroll(uiScroll, 0);
	ShowScroll(uiScroll2, 0);

	if (a == UI2_PLAY_GAME)
	{
		a = UI2_BEGIN;
		if (GetAppState() == APPSTATE_GAME_OVER)
		{
			int res = GetGameOverResult();
			if (res == GAMEOVER_NEXT_ROUND)
				ActivateUI(UI2_NET_ROUND_OVER);
			else
				ActivateUI(UI2_NET_GAME_OVER);
			return;
		} if (var_netMode!=NET_MODE_NONE && var_netMode!=NET_MODE_OFFLINE && var_dedicatedServer && IsServer())
		{
			ActivateUI(UI2_DEDICATED_SERVER);
			return;
		}
		else if (IsSpectatorMode())
		{
			ActivateUI(UI2_SPECTATOR_MENU);
			return;
		}
		else
		{
			int c = GetPlayerChara();
			if (c && IsCharaSpectatorMode(c))
			{
				ActivateUI(UI2_FOLLOW_MENU);
				return;
			}
		}
	}

	if (a==0 || a==UI2_BEGIN)
	{
		if (g_lastActiveUI==UI2_NET_ROUND_OVER)
			FadeIn(0.3);
		Activate(uiRoot, 0);
		Activate(uiBackground, 0);
		RenderWorld(1);		// render world
	} else if (a == UI2_DEDICATED_SERVER)
	{
		if (g_lastActiveUI==UI2_BEGIN || g_lastActiveUI==UI2_NET_ROUND_OVER)
			FadeIn(0.3);
		ShowPage(uiDedicatedServer, 0);
	} else if (a == UI2_RECEIVE_GAME_WORLD)
	{
		ShowPage(uiReceiveGameWorld, 0);
	} else if (a == UI2_SPECTATOR_MENU)
	{
		if (g_lastActiveUI==UI2_BEGIN || g_lastActiveUI==UI2_RECEIVE_GAME_WORLD || g_lastActiveUI==UI2_NET_ROUND_OVER)
			FadeIn(0.3);
		ShowPage(uiSpectatorMenu, 0);
	} else if (a == UI2_FOLLOW_MENU)
	{
		ShowPage(uiFollowMenu, 0);
	} else if (a == UI2_STAGE_CLEAR)
	{
		FadeIn(0.3);
		ShowPage(uiStageClear, 2);
		PlayMusic("win");
	} else if (a == UI2_GAME_OVER)
	{
		ShowPage(uiGameOver, 1);
		StopMusic(0.2);
		PlayMusic("gameover", 0, 0.2);
	} else if (a == UI2_NET_ROUND_OVER)
	{
		ShowPage(uiNetRoundOver, 1);
		StopMusic(0.2);
		PlayMusic("gameover", 0, 0.2);
	}  else if (a == UI2_NET_GAME_OVER)
	{
		if (GetGameOverResult() == GAMEOVER_COMPETITION_HOST_WIN)
			ShowPage(uiCompetitionHostWin, 1);
		else
			ShowPage(uiNetGameOver, 1);
		StopMusic(0.2);
		PlayMusic("gameover", 0, 0.2);
	}  else if (a == UI2_TRAINING_MENU)
	{
		ShowPage(uiTrainingMenu, 0);
	}  else if (a == UI2_TRAINING_OVER1)
	{
		ShowPage(uiTrainingOver1, 0);
		PlayMusic("win");
	}  else if (a == UI2_TRAINING_OVER2)
	{
		ShowPage(uiTrainingOver2, 0);
		PlayMusic("win");
	} else if (a == UI2_PONG)
	{
		ShowPage(uiPong, 1);
	} else if (a == UI2_START_MENU)
	{
		ShowPage(uiStartMenu, 0);
	} else if (a == UI2_INGAME_SCORE_BOARD)
	{
		ShowPage(uiInGameScoreboard, 0);
	} else if (a == UI2_MISSION_OBJECTIVE)
	{
		ShowPage(uiMissionObjective, 0);
	} else if (a == UI2_CONFIRM_LEAVE_GAME)
	{
		ShowPage(uiConfirmLeaveGame, 0);
	} else if (a == UI2_CONFIRM_JOIN_OTHER_GAME)
	{
		ShowPage(uiConfirmJoinOtherGame, 0);
	} else if (a == UI2_SESSION_NOT_COMPATIBLE)
	{
		ShowPage(uiSessionNotCompatible, 0);
	} else if (a == UI2_AUTO_DEMO)
	{
		FadeIn(0.3);
		if (var_uiAutoDemoSelection == "credit")
			ShowPage(uiCredit, 0);
		else
			ShowPage(uiAutoDemo, 0);
	} else if (a == UI2_SETTING_MENU)
	{
		SelectOptionItemValue(uiMusicVolumeOption, var_stMusicVolume);
		SelectOptionItemValue(uiEffectsVolumeOption, var_stEffectsVolume);
		SelectOptionItemValue(uiVoiceVolumeOption, var_stVoiceVolume);
		SelectOptionItemValue(uiVideoGammaOption, var_stVideoGamma);
		SelectOptionItemValue(uiVideoBrightnessOption, var_stVideoBrightness);
		SelectOptionItemValue(uiVideoContrastOption, var_stVideoContrast);
		SelectOptionItemValue(uiControllerVibrationOption, var_stControllerVibration);
		SelectOptionItemValue(uiCameraInvertOption, var_stCameraInvert);
		SelectOptionItemValue(uiShowPlayerName, var_stShowPlayerName);
		ShowPage(uiSettingMenu, 0);
	} else if (a == UI2_SETTING_LIVE)
	{
		SelectOptionItemValue(uiAppearOfflineOption, var_stAppearOffline);
		SelectOptionItemValue(uiVoiceThroughSpeaker, IsVoiceThroughSpeaker());
		SelectOptionItemValue(uiVoiceSpeakerVolume, GetVoiceThroughSpeakerVolume()*100+0.001); // fix float number round error
		ShowPage(uiSettingLiveMenu, 0);
	} else if (a == UI2_COMBO_TABLE)
	{
		ShowPage(uiComboTable, 0);
	} else if (a == UI2_KICK_MENU)
	{
		ShowPage(uiKickMenu, 0);
	} else if (a == UI2_CONFIRM_KICK)
	{
		ShowPage(uiConfirmKick, 0);
	} else if (a == UI2_BACKGROUND)
	{
		ShowPage(-1, 1);
	}
}

void LeaveGame()
{
	FadeOut(0.4);
	WaitScreenEffect();

	if (var_netMode == NET_MODE_INTERNET)
		SetAppState(APPSTATE_INTERNET_MENU);
	else if (var_netMode == NET_MODE_LAN)
		SetAppState(APPSTATE_LAN_MENU);
	else
	{
		if (var_uiMissionSelection == "TRAINING")
			SetAppState(APPSTATE_MAIN_MENU);
		else
			SetAppState(APPSTATE_SINGLE_MENU);
	}

	FadeIn(0.4);
}

void ShowLiveNotification(int id)
{
	int icon = 0;
	Begin(id);
		if (IsShowGameInvite())
			icon = iconGameInvite;
		else if (IsShowFriendRequest())
			icon = iconFriendRequest;

		if (icon)
		{
			Show();
			Image(icon);
		} else
		{
			Show(0);
		}
	End();
}

void ShowLoginState(int id)
{
	Begin(id);
		Show();
		int s = GetLoginLiveState();
		if (s == LOGIN_NOT_SIGNED_IN)
			Text(STR_NOT_SIGNED_IN);
		else if (s == LOGIN_FAILED)
			Text(STR_SIGN_IN_FAILED);
		else if (s == LOGIN_SUCCEEDED)
			Text(GetWStringFromTable(STR_SIGNED_IN)+GetLiveUserName());
		else if (s == LOGIN_PASSCODE_NEEDED)
			Text(STR_PASSCODE_NEEDED);
		else
			Text("");
	End();
}

void FlashArrow(int frame)
{
	if (frame == 0)
	{
		TweenTextColor(1,1,1,0, 1,1,1,1, 0.2);
		NextFrame(0.5);
	} else
	{
		TweenTextColor(1,1,1,1, 1,1,1,0, 0.2);
		NextFrame(0.2, 0);
	}
}

int IsTeamRule()
{
	return var_rule==RULE_TEAM_DEATH_MATCH || var_rule==RULE_VIP || var_rule==RULE_GIANT_KILL || var_rule==RULE_CUSTOM2;
}

int IsFairTeamRule()
{
	// not including giant kill
	return var_rule==RULE_TEAM_DEATH_MATCH || var_rule==RULE_VIP || var_rule==RULE_CUSTOM2;
}


//////////// in game players
void ShowInGamePlayers()
{
	BeginChild(2);		// title
		Text(var_rule+STR_SCORE_TITLE_BEGIN);
	End();
	BeginChild(5); Text(var_rule+STR_RULE_SCENARIO); End();

	Begin(uiInGamePlayers);
	int i, j, p, c, team;

	for (i=0; i<16; i++)
	{
		BeginChild(i);
			BeginChild(0); TextColor(0,0,0,0); End();
			BeginChild(1); TextColor(0,0,0,0); End();
			BeginChild(2); TextColor(0,0,0,0); End();
		End();
	}

	int n = GetNumPlayers();
	if (n > 16)
		n = 16;

	int t = 0;
	float r,g,b;
	int me = GetLocalPlayer();
	int stampX, stampY;

	int scoreIdx = 0;
	if (var_rule==RULE_VIP)
		scoreIdx = 2;
	else if (var_rule==RULE_GIANT_KILL)
		scoreIdx = 1;

	for (i=0; i<n; i++)
	{
		p = GetPlayer(i);
		if (p == 0)
			continue;
		team = GetPlayerSelectTeam(p);
		if (team==1)
		{
			r = teamColorR[1]; g = teamColorG[1]; b = teamColorB[1];
		} else if (team==2)
		{
			r = teamColorR[2]; g = teamColorG[2]; b = teamColorB[2];
		} else
		{
			r = teamColorR[0]; g = teamColorG[0]; b = teamColorB[0];
		}
		BeginChild(t);
			BeginChild(0); TextColor(r,g,b); Text(GetPlayerDisplayName(p)); End();
			c = GetPlayerChara(p);
			if (c)
			{
				BeginChild(1); TextColor(r,g,b); Number(GetCharaScore(c, scoreIdx)); End();
				BeginChild(2); TextColor(r,g,b); Number(GetCharaScore(c, scoreIdx)+GetCharaTotalScore(c, scoreIdx)); End();
			}
			if (p == me)
			{
				stampX = GetX();
				stampY = GetY();
			}
		End();
		t++;
	}
	End();

	BeginChild(4);		// arrow
		if (me && var_uiShowInGamePlayers)
		{
			Show();
			Position(stampX-5, stampY-2);
		} else
			Show(0);
	End();

	BeginChild(7);
		int txt = GetTextID();
		if (IsTeamRule() && !IsCompetitionSession())
		{
			if (IsRoundStart())
				Text(BUT_SPECTATOR_TEAM_FIGHT);
			else if (IsServer())
				Text(BUT_SPECTATOR_TEAM_SV);
			else
				Text(BUT_SPECTATOR_TEAM_CL);
		} else
		{
			if (IsRoundStart())
				Text(BUT_SPECTATOR_FIGHT);
			else if (IsServer())
			{
				if (IsCompetitionSession())
					Text(BUT_SPECTATOR_CL);		// no "Ready" button
				else
					Text(BUT_SPECTATOR_SV);
			}
			else
				Text(BUT_SPECTATOR_CL);
			if (var_rule == RULE_ONE_ON_ONE)	// 1on1 spectator message (no free camera)
				Text(GetTextID()+1);
		}
	End();

	BeginChild(8);
		if (IsCompetitionSession() && !IsRoundStart())
			SetUITime(GetID(), GetCompetitionCountDown());
		else
			Show(0);
	End();
}

void SpectatorMenu_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowInGamePlayers();

		if (var_uiShowInGamePlayers)
			ShowScroll(uiScroll, 9);
		ShowChild(0, 0);
		ShowChild(1, 0);
		ShowChild(2, 0);
		ShowChild(3, 0);
		ShowChild(4, 0);
		ShowChild(5, 0);
		ShowChild(6, 0);
		ShowChild(8, 0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		if (var_uiShowInGamePlayers)
		{
			ShowChild(0, 1);
			ShowChild(1, 1);
			ShowChild(2, 1);
			ShowChild(3, 1);
			ShowChild(4, 1);
			ShowChild(5, 1);
			ShowChild(6, 0);
			ShowChild(8, 1);
		} else
		{
			ShowChild(0, 0);
			ShowChild(1, 0);
			ShowChild(2, 0);
			ShowChild(3, 0);
			ShowChild(4, 0);
			ShowChild(5, 0);
			ShowChild(6, 1);
			ShowChild(8, 0);
		}
		ShowInGamePlayers();
		NextFrame(0.1);
	} else if (frame == 2)
	{
		ShowInGamePlayers();
		NextFrame(0.1, 2);
	}
}

int SpectatorMenu_OnInput(int key)
{
	if ((key==BUTTONKEY_PAD_LEFT || key==BUTTONKEY_PAD_RIGHT) && !IsCompetitionSession())
	{
		if (IsTeamRule())
		{
			int team = GetPlayerSelectTeam(GetLocalPlayer());
			if (team == 1)
				team = 2;
			else
				team = 1;
			PlayerSelectTeam(GetLocalPlayer(), team);
			PlaySound(sndPadY);
		}
		return 1;
	} else if (IsButtonX(key))
	{
		if (var_rule != RULE_ONE_ON_ONE)
		{
			SetCameraMode(0);
			PlaySound(sndSel);
		}
	} else if (IsButtonY(key))
	{
		SetCameraMode(1);
		SetCameraNextTarget();
		PlaySound(sndSel);
	} else if (IsButtonA(key))
	{
		int txt;
		BeginChild(7); txt=GetTextID(); End();
		if (txt==BUT_SPECTATOR_SV || txt==BUT_SPECTATOR_TEAM_SV || txt==BUT_SPECTATOR_SV_1ON1)
		{
			RoundStart();
			PlaySound(sndOK);
			ShowInGamePlayers();
		}
		else if (txt==BUT_SPECTATOR_TEAM_FIGHT || txt==BUT_SPECTATOR_FIGHT || txt==BUT_SPECTATOR_FIGHT_1ON1)
		{
			SetAppState(APPSTATE_LEAVE_SPECTATOR_MODE);
			PlaySound(sndOK);
		}
		return 1;
	} else if(IsButtonWhite(key))
	{
		var_uiShowInGamePlayers = 1 - var_uiShowInGamePlayers;
		ActivateUI(UI2_SPECTATOR_MENU);
	}

	return 0;
}

int FollowMenu_OnInput(int key)
{
	if (IsButtonY(key))
	{
		SetCameraNextTarget();
		PlaySound(sndSel);
	}

	return 0;
}

////////////// game over
void GameOver_OnAnimate(int frame)
{
	if (frame == 0)
	{
		if (var_uiGameOverVoice1 != "")
			PlayVoice(var_uiGameOverVoice1);

		Show(0);
		EnableInput(0);
		NextFrame(0.2);
	} else if (frame == 1)
	{
		if (IsVoicePlaying())
			NextFrame(0.2, 1);		// check voice again
		else
		{
			if (var_uiGameOverVoice2 != "")
				PlayVoice(var_uiGameOverVoice2);

			ShowScroll(uiScroll, 8);
			NextFrame(0.1);
		}
	} else if (frame == 2)
	{
		Show();
		EnableInput();
	}
}

int GameOver_OnInput(int key)
{
	if (IsButtonA(key))
	{
		// play game again
		StopVoice();
		PlaySound(sndOK);
		if (GetGameOverResult() == GAMEOVER_CONTINUE)
			SetAppState(APPSTATE_CONTINUE_SINGLE);
		else
			SetAppState(APPSTATE_START_SINGLE);
		return 1;
	} else if (IsButtonB(key))
	{
		// quit game
		PlaySound(sndSel);
		StopVoice();
		LeaveGame();
		return 1;
	}

	return 0;
}

////////////// unlock feature
int Unlock_OnInput(int key)
{
	if (IsButtonA(key))
	{
		PlaySound(sndOK);
		// close window
		Activate(uiUnlock, 0);

		// animate stage clear again
		PlayUIAnimation(uiStageClear, 2);
		return 1;
	}

	return 0;
}

int g_charaScoreTable[16];
g_charaScoreTable[0] = 3000;
g_charaScoreTable[1] = 6500;
g_charaScoreTable[2] = 10500;
g_charaScoreTable[3] = 15000;
g_charaScoreTable[4] = 20000;
g_charaScoreTable[5] = 25500;
g_charaScoreTable[6] = 31500;
g_charaScoreTable[7] = 38000;
g_charaScoreTable[8] = 45000;
g_charaScoreTable[9] = 52500;
g_charaScoreTable[10] = 60500;
g_charaScoreTable[11] = 69000;
g_charaScoreTable[12] = 78000;
g_charaScoreTable[13] = 87500;
g_charaScoreTable[14] = 97500;
g_charaScoreTable[15] = 108000;
int g_charaUnlockIndex[16];
g_charaUnlockIndex[0] = 5;
g_charaUnlockIndex[1] = 9;
g_charaUnlockIndex[2] = 23;
g_charaUnlockIndex[3] = 7;
g_charaUnlockIndex[4] = 17;
g_charaUnlockIndex[5] = 19;
g_charaUnlockIndex[6] = 20;
g_charaUnlockIndex[7] = 21;
g_charaUnlockIndex[8] = 11;
g_charaUnlockIndex[9] = 12;
g_charaUnlockIndex[10] = 13;
g_charaUnlockIndex[11] = 14;
g_charaUnlockIndex[12] = 15;
g_charaUnlockIndex[13] = 25;
g_charaUnlockIndex[14] = 26;
g_charaUnlockIndex[15] = 10;
int g_weaponUnlockTable[7];
g_weaponUnlockTable[0] = 72;
g_weaponUnlockTable[1] = 62;
g_weaponUnlockTable[2] = 42;
g_weaponUnlockTable[3] = 92;
g_weaponUnlockTable[4] = 82;
g_weaponUnlockTable[5] = 52;
g_weaponUnlockTable[6] = 12;

int CheckUnlock(int type, int idx)
{
	// Chara
	if (type == 1)
	{
		if (IsCharaLocked(g_charaTable[idx]))
		{
			Begin(uiUnlock);
				BeginChild(1);
					Text(STR_UNLOCK_CHAR);
				End();
				BeginChild(2);
					Text(NAME_CE01+idx);
				End();
			End();
			UnlockChara(g_charaTable[idx]);
			Activate(uiUnlock, 1);
			return 1;
		}
	}
	// Weapon
	else if (type == 2)
	{
		if (IsWeaponLocked(idx))
		{
			if (idx%10)
			{
				if (IsWeaponLocked(idx-2))
					return 0;

				Begin(uiUnlock);
					BeginChild(1);
						Text(STR_UNLOCK_WEAPON);
					End();
					BeginChild(2);
						Text(NAME_WPN1+idx/10+8);
					End();
				End();
			}
			else
			{
				Begin(uiUnlock);
					BeginChild(1);
						Text(STR_UNLOCK_WEAPON);
					End();
					BeginChild(2);
						Text(NAME_WPN1+idx/10-1);
					End();
				End();
			}
			UnlockWeapon(idx);
			Activate(uiUnlock, 1);
			return 1;
		}
	}
	// Movie
	else if (type == 3)
	{
		if (IsMovieLocked(idx))
		{
			Begin(uiUnlock);
				BeginChild(1);
					Text(STR_UNLOCK_MOVIE);
				End();
				BeginChild(2);
					Text(MOV_01+idx-1);
				End();
			End();
			UnlockMovie(idx);
			Activate(uiUnlock, 1);
			return 1;
		}
	}
	// Attack
	else if (type == 4)
	{
		if (idx <= GetUnlockAction() ) return 0;
		wstring txt;
		if (idx < 6)
		{
			Begin(uiUnlock);
				BeginChild(1);
					Text(STR_UNLOCK_ATTACK);
				End();
				BeginChild(2);
					Text(-1);
					if (idx % 2)
						txt = GetWStringFromTable(NAME_WPN2, 0)
							+ GetWStringFromTable(WPN_LV1+(idx/2)%3, 0);		// use string table 0
					else
						txt = GetWStringFromTable(NAME_WPN3, 0)
							+ GetWStringFromTable(WPN_LV1+(idx/2)%3, 0);		// use string table 0
					Text(txt);
				End();
			End();
			Activate(uiUnlock, 1);
			return 1;
		}
		else
		{
			if (IsWeaponLocked(g_weaponUnlockTable[idx/3-2]-2))
				return 0;
			Begin(uiUnlock);
				BeginChild(1);
					Text(STR_UNLOCK_ATTACK);
				End();
				BeginChild(2);
					Text(-1);
					txt = GetWStringFromTable(NAME_WPN1+g_weaponUnlockTable[idx/3-2]/10-1, 0)
						+ GetWStringFromTable(WPN_LV1+idx%3, 0);		// use string table 0
					Text(txt);
				End();
			End();
			Activate(uiUnlock, 1);
			return 1;
		}
	}
	return 0;
}

int UnlockFeature(int type, int score)
{
	// unlock character & weapon B
	if (type == 1)
	{
		for (int i = 0 ; i < 16 ; i++)
		{
			if (score > g_charaScoreTable[i])
				if ( CheckUnlock(1, g_charaUnlockIndex[i]) ) return 1;
		}
		for (i = 0 ; i < 7 ; i++)
		{
			if (score > g_charaScoreTable[i])
				if ( CheckUnlock(2, g_weaponUnlockTable[i]) ) return 1;
		}
	}
	// unlock weapon A and movie
	else if (type == 2)
	{
		if (var_uiMissionSelection == "SE01")
		{
			if ( CheckUnlock(3, 1) ) return 1;
			if (var_uiCharaSelection == "CE01")
			{
				if ( CheckUnlock(3, 2) ) return 1;
				if ( CheckUnlock(3, 3) ) return 1;
			}
			else if (var_uiCharaSelection == "CE03")
			{
				if ( CheckUnlock(3, 4) ) return 1;
				if ( CheckUnlock(3, 5) ) return 1;
			}
		}
		else if (var_uiMissionSelection == "SE02")
		{
			if ( CheckUnlock(3, 6) ) return 1;
			if ( CheckUnlock(2, 70) ) return 1;
		}
		else if (var_uiMissionSelection == "SE04")
		{
			if ( CheckUnlock(3, 7) ) return 1;
			if ( CheckUnlock(2, 60) ) return 1;
		}
		else if (var_uiMissionSelection == "SE06")
		{
			if ( CheckUnlock(3, 8) ) return 1;
			if ( CheckUnlock(2, 40) ) return 1;
		}
		else if (var_uiMissionSelection == "SW02")
		{
			if ( CheckUnlock(3, 9) ) return 1;
			if ( CheckUnlock(2, 90) ) return 1;
		}
		else if (var_uiMissionSelection == "SW03")
		{
			if ( CheckUnlock(3, 10) ) return 1;
			if ( CheckUnlock(2, 80) ) return 1;
		}
		else if (var_uiMissionSelection == "SW04")
		{
			if ( CheckUnlock(3, 11) ) return 1;
			if ( CheckUnlock(2, 50) ) return 1;
		}
		else if (var_uiMissionSelection == "SW05")
		{
			if ( CheckUnlock(3, 12) ) return 1;
			if ( CheckUnlock(2, 10) ) return 1;
		}
		else if (var_uiMissionSelection == "SE08")
		{
			if (var_uiCharaSelection == "CE01")
			{
				if ( CheckUnlock(3, 13) ) return 1;
				if ( CheckUnlock(3, 14) ) return 1;
			}
			else if (var_uiCharaSelection == "CE03")
			{
				if ( CheckUnlock(3, 15) ) return 1;
				if ( CheckUnlock(3, 16) ) return 1;
			}
		}
		else if (var_uiMissionSelection == "SE09")
		{
			if (var_uiCharaSelection == "CE01")
			{
				if ( CheckUnlock(3, 17) ) return 1;
			}
			else if (var_uiCharaSelection == "CE03")
			{
				if ( CheckUnlock(3, 18) ) return 1;
			}

			// all stage clear
			if ( CheckUnlock(1, 1) ) return 1;
			if ( CheckUnlock(1, 3) ) return 1;
			if ( CheckUnlock(1, 4) ) return 1;
			if ( CheckUnlock(1, 6) ) return 1;
			if ( CheckUnlock(1, 8) ) return 1;
			if ( CheckUnlock(1, 16) ) return 1;
			if ( CheckUnlock(1, 18) ) return 1;
			if ( CheckUnlock(1, 22) ) return 1;
			if ( CheckUnlock(2, 22) ) return 1;
			if ( CheckUnlock(2, 32) ) return 1;
		}
	}
	// unlock attack
	else if (type == 3)
	{
		for (i = 0 ; i < (score/8000) ; i++)
		{
			if (i > 23)
				break;
			
			if (i < 3)
			{
				if ( CheckUnlock(4, i*2) )
				{
					SetUnlockAction(i*2);
					return 1;
				}
				if ( CheckUnlock(4, i*2+1) )
				{
					SetUnlockAction(i*2+1);
					return 1;
				}
			}
			else
			{
				if ( CheckUnlock(4, i+3) )
				{
					SetUnlockAction(i+3);
					return 1;
				}
			}
		}
	}

	return 0;
}

////////////// counter UI
void Counter_OnAnimate(int frame)
{
	int result, current, module;
	int i;

	// if skip or over, do nothing
	Begin(uiStageClear);
		i = GetNumber();
	End();
	if (i >= 9)
		return;

	if (frame == 0)
	{
		BeginChild(0);
			result = GetNumber();
		End();
		BeginChild(1);
			Number(0);
		End();
		Show(1);
		if (result <= 0)
			NextFrame(0.2, 2);
		else
			NextFrame(0.2, 1);
	}
	else if (frame == 1)
	{
		BeginChild(0);
			result = GetNumber();
		End();
		BeginChild(1);
			current = GetNumber();
			module = 10;
			for (i = 0 ; i < 9 ; i++)
			{
				if (result <= current) break;
				if ( (result % module) > (current % module) )
				{
					current = current + module/10;
					Number(current);
					break;
				}
				module = module * 10;
			}
		End();
		if (result > current)
			NextFrame(0.1, 1);
		else
			NextFrame(0.1, 2);
	}
	else if (frame == 2)
	{
		Begin(uiStageClear);
			Number(GetNumber()+1);
			NextFrame(0.5, 1);
		End();
	}
}

int NewCounterItem(int x, int y)
{
	int id = NewUI();
	Begin(id);
		Begin(NewUI());
			Number(0); Show(0);
		End();
		Begin(NewUI());
			Position(x, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); ShowNumber(0);
		End();
		EventHandler("OnAnimate", "Counter_OnAnimate");
	End();
	return id;
}

////////////// stage clear
void StageClear_OnAnimate(int frame)
{
	int i;

	if (frame == 0)
	{
		ShowScroll(uiScroll, 1);
		Show(0);
		Begin(uiStageClear);
			Number(0);
			// hide all number
			for (i = 0 ; i < 6 ; i++)
			{
				BeginChild(3*i+2);
					Show(0);
				End();
				BeginChild(3*i+3);
					Show(0);
				End();
			}
			BeginChild(20);
				Show(0);
			End();
			BeginChild(22);
				Show(0);
			End();
			BeginChild(24);
				Show(0);
			End();
		End();
		NextFrame(0.6);
	} else if (frame == 1)
	{
		Show();
		int c = GetPlayerChara();
		Begin(uiStageClear);
			i = GetNumber();
			if (i == 3)
			{
				BeginChild(3*i+2);
					Show(1);
					if (GetCharaScore(c, i) == 1)
						Text("Yes");
					else
						Text("No");
				End();
				BeginChild(3*i+3);
					BeginChild(0);
						Number(GetCharaTotalScore(c, i));
					End();
 					NextFrame(0.1, 0);
				End();
			}
			else if ( (i >= 0) && (i < 5) )
			{
				if (i == 4) // phoenix stone (cancelled)
				{
					Number(5);
					NextFrame(0.1, 1);
				}
				else
				{
					BeginChild(3*i+2);
						Number(GetCharaScore(c, i)); Show(1);
					End();
					BeginChild(3*i+3);
						BeginChild(0);
							Number(GetCharaTotalScore(c, i));
						End();
						NextFrame(0.1, 0);
					End();
				}
			}
			else if (i == 5)
			{
				// time
				BeginChild(17);
					Show(1);
					int sec = GetCharaScore(c, 5);
					Text(NumToStr("%d", sec/3600) + ":" + NumToStr("%02d", (sec/60)%60) + ":" + NumToStr("%02d", sec%60));
				End();
				BeginChild(18);
					BeginChild(0);
						Number(GetCharaTotalScore(c, 5));
					End();
					NextFrame(0.1, 0);
				End();
			}
			else if (i == 6)
			{
				// stage score
				int stageScore = 0;
				for (int j = 0 ; j < 6 ; j++)
				{
					stageScore = stageScore + GetCharaTotalScore(c, j);
				}
				SetTotalScore(GetTotalScore()+stageScore);
				BeginChild(20);
					BeginChild(0);
						Number(stageScore);
					End();
					NextFrame(0.1, 0);
				End();
			}
			else if (i == 7)
			{
				// total time
				BeginChild(22);
					Show(1);
					sec = GetTotalGameTime();
					Text(NumToStr("%d", sec/3600) + ":" + NumToStr("%02d", (sec/60)%60) + ":" + NumToStr("%02d", sec%60));
				End();
				Number(GetNumber()+1);
				NextFrame(0.5, 1);
			}
			else if (i == 8)
			{
				// total score
				BeginChild(24);
					BeginChild(0);
						Number(GetTotalScore());
					End();
					NextFrame(0.1, 0);
				End();
			}
		End();
		if (i >= 9)
			NextFrame(0.2);
	} else if (frame == 2)
	{
		EnableInput(0);
		// unlock feature
		if ( UnlockFeature(1, GetTotalScore()) )
			return;
		if ( UnlockFeature(2, 0) )
			return;
		if ( UnlockFeature(3, GetTotalStones()) )
			return;
		EnableInput();
		Begin(uiStageClear);
			Number(10);
		End();
	}
}

int StageClear_OnInput(int key)
{
	if (IsButtonA(key))
	{
		int i;
		int c = GetPlayerChara();
		// if animate not over
		Begin(uiStageClear);
			i = GetNumber();
		End();
		if ( (i > 0) && (i < 9) )
		{
			Begin(uiStageClear);
				for (; i < 9 ; i++)
				{
					if (i == 3)
					{
						BeginChild(3*i+2);
							Show(1);
							if (GetCharaScore(c, i) == 1)
								Text("Yes");
							else
								Text("No");
						End();
						BeginChild(3*i+3);
							Show(1);
							BeginChild(0);
								Number(GetCharaTotalScore(c, i));
							End();
							BeginChild(1);
								Number(GetCharaTotalScore(c, i));
							End();
						End();
					}
//					else if ( (i >= 0) && (i < 5) )
					else if ( (i >= 0) && (i < 4) )
					{
						BeginChild(3*i+2);
							Number(GetCharaScore(c, i)); Show(1);
						End();
						BeginChild(3*i+3);
							Show(1);
							BeginChild(0);
								Number(GetCharaTotalScore(c, i));
							End();
							BeginChild(1);
								Number(GetCharaTotalScore(c, i));
							End();
						End();
					}
					else if (i == 5)
					{
						// time
						BeginChild(17);
							Show(1);
							int sec = GetCharaScore(c, 5);
							Text(NumToStr("%d", sec/3600) + ":" + NumToStr("%02d", (sec/60)%60) + ":" + NumToStr("%02d", sec%60));
						End();
						BeginChild(18);
							Show(1);
							BeginChild(0);
								Number(GetCharaTotalScore(c, 5));
							End();
							BeginChild(1);
								Number(GetCharaTotalScore(c, 5));
							End();
						End();
					}
					else if (i == 6)
					{
						// stage score
						int stageScore = 0;
						for (int j = 0 ; j < 6 ; j++)
						{
							stageScore = stageScore + GetCharaTotalScore(c, j);
						}
						SetTotalScore(GetTotalScore()+stageScore);
						BeginChild(20);
							Show(1);
							BeginChild(0);
								Number(stageScore);
							End();
							BeginChild(1);
								Number(stageScore);
							End();
						End();
					}
					else if (i == 7)
					{
						// total time
						BeginChild(22);
							Show(1);
							sec = GetTotalGameTime();
							Text(NumToStr("%d", sec/3600) + ":" + NumToStr("%02d", (sec/60)%60) + ":" + NumToStr("%02d", sec%60));
						End();
					}
					else if (i == 8)
					{
						// total score
						BeginChild(24);
							Show(1);
							BeginChild(0);
								Number(GetTotalScore());
							End();
							BeginChild(1);
								Number(GetTotalScore());
							End();
						End();
					}
				}
				Number(9);
				NextFrame(0.1, 2);
			End();
		}
		else if (i == 10)
		{
			ClearMission(var_uiMissionSelection);
			PlaySound(sndOK);
			FadeOut(0.4);
			WaitScreenEffect();
			SetAppState(APPSTATE_SINGLE_MENU);
			ForceNextUI(UI_SAVE_MENU);
			return 1;
		}
	}

	return 0;
}

////////////// net round over
int FindCharaByRoundRank(int rank)
{
	int i;
	int s = GetNumCharas();
	for (i=0; i<s; i++)
	{
		int c = GetChara(i);
		if (c == 0)
			continue;
		if (GetCharaRoundRank(c) == rank)
			return c;
	}
	return 0;
}

int g_team1Score;
int g_team2Score;
int g_team1WinRound;
int g_team2WinRound;
int g_team1TotalScore;
int g_team2TotalScore;
void ComputeTeamScore()
{
	g_team1Score = 0;
	g_team2Score = 0;
	g_team1TotalScore = 0;
	g_team2TotalScore = 0;
	g_team1WinRound = GetWinRound(1);
	g_team2WinRound = GetWinRound(2);

	int i;
	int s = GetNumCharas();
	for (i=0; i<s; i++)
	{
		int c = GetChara(i);
		int team = GetCharaAttrib(c, CHARA_TEAM);
		int score = GetCharaScore(c, 0);
		int totalScore = GetCharaTotalScore(c, 3);
		if (team == 1)
		{
			g_team1Score = g_team1Score + score;
			g_team1TotalScore = g_team1TotalScore + totalScore;
		}
		else if (team == 2)
		{
			g_team2Score = g_team2Score + score;
			g_team2TotalScore = g_team2TotalScore + totalScore;
		}
	}
}

void ShowTeamScore(int t1, int t2, int s1, int s2)
{
	int tm1, tm2;
	CountCharaTeamMembers(tm1, tm2);

	Begin(t1);
		Show();
		if (tm1 > 0)
			Text(NumToStr(s1));
		else
			Text("X");
		TextColor(teamColorR[1], teamColorG[1], teamColorB[1]);
	End();

	Begin(t2);
		Show();
		if (tm2 > 0)
			Text(NumToStr(s2));
		else
			Text("X");
		TextColor(teamColorR[2], teamColorG[2], teamColorB[2]);
	End();
}

void ShowRoundScore()
{
	int useTeam = 0;
	// change score borad text according to different rules
	if (var_rule == RULE_ONE_ON_ONE)
	{
		Begin(uiRoundScoreListTitle);
			SetChildText(2, STR_CHAMPION);
			SetChildText(3, STR_CHAMP_DURATION);
			SetChildText(4, STR_TOP_RING);
		End();
	}
	else if (var_rule==RULE_DEATH_MATCH || var_rule==RULE_CUSTOM1)
	{
		Begin(uiRoundScoreListTitle);
			SetChildText(2, STR_KILL);
			SetChildText(3, STR_SERIAL_KILL);
			SetChildText(4, STR_DEATH);
		End();
	}
	else if (var_rule==RULE_TEAM_DEATH_MATCH || var_rule==RULE_CUSTOM2)
	{
		Begin(uiRoundScoreListTitle);
			SetChildText(2, STR_KILL);
			SetChildText(3, STR_SERIAL_KILL);
			SetChildText(4, STR_DEATH);
		End();
		useTeam = 1;
	}
	else if (var_rule == RULE_VIP)
	{
		Begin(uiRoundScoreListTitle);
			SetChildText(2, STR_KILL_VIP);
			SetChildText(3, STR_RESCUE);
			SetChildText(4, STR_KILL);
		End();
		useTeam = 1;
	}
	else if (var_rule == RULE_GIANT_KILL)
	{
		Begin(uiRoundScoreListTitle);
			SetChildText(2, STR_G_KILL);
			SetChildText(3, STR_DAMAGE_GIANT);
			SetChildText(4, STR_DEATH);
		End();
		useTeam = 1;
	}
	else
	{
		Begin(uiRoundScoreListTitle);
			SetChildText(2, STR_KILL);
			SetChildText(3, STR_SERIAL_KILL);
			SetChildText(4, STR_DEATH);
		End();
	}

	Begin(uiRoundScoreList);

	int me = GetPlayerChara();
	float r,g,b;

	int i, c, stampX, stampY;
	int s = NumChildren();
	for (i=0; i<s; i++)
	{
		BeginChild(i);
		c = FindCharaByRoundRank(i);

		int team = GetCharaAttrib(c, CHARA_TEAM);
		if (useTeam && team==1)
		{
			r = teamColorR[1]; g = teamColorG[1]; b = teamColorB[1];
		} else if (useTeam && team==2)
		{
			r = teamColorR[2]; g = teamColorG[2]; b = teamColorB[2];
		} else
		{
			r = teamColorR[0]; g = teamColorG[0]; b = teamColorB[0];
		}

		if (c==me && c!=0)
		{
			stampX = GetX();
			stampY = GetY();
		}

		if (c)
		{
			BeginChild(0); TextColor(r,g,b); Number(GetCharaRoundRank(c)+1); End();
			BeginChild(1); TextColor(r,g,b); Text(GetCharaDisplayName(c)); End();
			BeginChild(2); TextColor(r,g,b); Number(GetCharaScore(c, 0)); End();
			BeginChild(3); TextColor(r,g,b); Number(GetCharaScore(c, 1)); End();
			BeginChild(4); TextColor(r,g,b); Number(GetCharaScore(c, 2)); End();
			BeginChild(5); TextColor(r,g,b); Number(GetCharaScore(c, 3)); End();
		} else
		{
			BeginChild(0); TextColor(0,0,0,0); End();
			BeginChild(1); TextColor(0,0,0,0); End();
			BeginChild(2); TextColor(0,0,0,0); End();
			BeginChild(3); TextColor(0,0,0,0); End();
			BeginChild(4); TextColor(0,0,0,0); End();
			BeginChild(5); TextColor(0,0,0,0); End();
		}

		End();
	}
	End();

	Begin(uiRoundScoreboard);
		BeginChild(4);		// arrow
			if (me)
			{
				Show();
				Position(stampX+70, stampY-2);
			} else
			{
				Show(0);
			}
		End();

		if (useTeam)
		{
			ComputeTeamScore();
			ShowTeamScore(GetChild(5), GetChild(6), g_team1Score, g_team2Score);
		}
		else
		{
			ShowChild(5, 0);
			ShowChild(6, 0);
		}

	End();
}


void NetRoundOver_OnAnimate(int frame)
{
	if (frame == 0)
	{
		EnableInput(0);
		ShowScroll(uiScroll, 7);
		Show(0);
		NextFrame(0.5);
		ShowRoundScore();
	} else if (frame == 1)
	{
		Show(1);
		Activate(uiRoundScoreboard, 1);
		NextFrame(5);
	} else if (frame == 2)
	{
		EnableInput(1);
	}
}

int NetRoundOver_OnInput(int key)
{
	if (IsButtonA(key) && IsServer())
	{
		SetAppState(APPSTATE_NEXT_ROUND);
		return 1;
	}

	return 0;
}


////////////// net game over
int FindCharaByTotalScoreRank(int rank)
{
	int i;
	int s = GetNumCharas();
	for (i=0; i<s; i++)
	{
		int c = GetChara(i);
		if (c == 0)
			continue;
		if (GetCharaTotalScoreRank(c) == rank)
			return c;
	}
	return 0;
}

wstring GetTeamName(int t)
{
	int i, p, team;
	int s = GetNumPlayers();
	for (i=0; i<s; i++)
	{
		p = GetPlayer(i);
		if (p == 0)
			continue;
		team = GetPlayerSelectTeam(p);
		if (team == t)
			return GetPlayerTeamName(p);
	}

	if (t == 1)
		return L"Team A";
	else
		return L"Team B";
}

void ShowFinalScore()
{
	Begin(uiFinalScoreboard);

	Begin(uiFinalScoreList);
	int i, j, c, team, useTeam;

	for (i=0; i<16; i++)
	{
		BeginChild(i);
			BeginChild(0); TextColor(0,0,0,0); End();
			BeginChild(1); TextColor(0,0,0,0); End();
			BeginChild(2); TextColor(0,0,0,0); End();
			BeginChild(3); Color(0,0,0,0,0); End();
		End();
	}

	int n = GetNumCharas();
	if (n > 16)
		n = 16;

	int t, t1, t2;
	t = t1 = t2 = 0;
	float r,g,b;
	int me = GetPlayerChara();
	int stampX, stampY;
	useTeam = IsFairTeamRule();

	for (i=0; i<n; i++)
	{
		if (useTeam)
			c = GetChara(i);
		else
			c = FindCharaByTotalScoreRank(i);
		if (c == 0)
			continue;
		team = GetCharaAttrib(c, CHARA_TEAM);
		if (team==1)
		{
			r = teamColorR[1]; g = teamColorG[1]; b = teamColorB[1];
			t = t1;
			t1++;
		} else if (team==2)
		{
			r = teamColorR[2]; g = teamColorG[2]; b = teamColorB[2];
			if (useTeam)
			{
				t = t2+8;
				t2++;
			} else
			{
				t = t1;
				t1++;
			}
		} else
		{
			r = teamColorR[0]; g = teamColorG[0]; b = teamColorB[0];
			t = t1;
			t1++;
		}
		BeginChild(t);
			BeginChild(0); TextColor(r,g,b); Text(GetCharaDisplayName(c)); End();
			BeginChild(1); TextColor(r,g,b); Number(GetCharaTotalScore(c, 3)); End();
			if (c == me)
			{
				stampX = GetX();
				stampY = GetY();
			}
		End();
	}
	End();

	BeginChild(5);		// arrow
		if (me != 0)
		{
			Show();
			Position(stampX, stampY-2);
		} else
			Show(0);
	End();

	if (useTeam || var_rule==RULE_GIANT_KILL)
	{
		ComputeTeamScore();
		BeginChild(3); Text(STR_FINAL_TEAM_SCORE); End();
		ShowTeamScore(GetChild(6), GetChild(7), g_team1WinRound, g_team2WinRound);
		ShowTeamScore(GetChild(8), GetChild(9), g_team1TotalScore, g_team2TotalScore);
		BeginChild(10);
			if (g_team1WinRound>g_team2WinRound || (g_team1WinRound==g_team2WinRound && g_team1TotalScore>g_team2TotalScore))
			{
				TextColor(teamColorR[1], teamColorG[1], teamColorB[1]);
				if (IsCompetitionSession())
					Text(GetTeamName(1)+GetWStringFromTable(STR_TEAM_WIN));
				else
					Text(STR_TEAM_A_WIN);
			}
			else if (g_team1WinRound<g_team2WinRound || (g_team1WinRound==g_team2WinRound && g_team1TotalScore<g_team2TotalScore))
			{
				TextColor(teamColorR[2], teamColorG[2], teamColorB[2]);
				if (IsCompetitionSession())
					Text(GetTeamName(2)+GetWStringFromTable(STR_TEAM_WIN));
				else
					Text(STR_TEAM_B_WIN);
			}
			else
			{
				TextColor(teamColorR[0], teamColorG[0], teamColorB[0]);
				if (IsCompetitionSession())
					Text(STR_COMPETITION_NO_WINNER);
				else
					Text(STR_NO_WINNER);
			}
			Position(400, 170); TextSize(38);
		End();
	}
	else
	{
		BeginChild(3); Text(STR_FINAL_WINNER); End();
		ShowChild(6, 0);
		ShowChild(7, 0);
		ShowChild(8, 0);
		ShowChild(9, 0);
		BeginChild(10);
			TextColor(0.9, 0.1, 0);
			Text(GetCharaDisplayName(FindCharaByTotalScoreRank(0)));
			Position(400, 170); TextSize(40);
		End();
	}
	End();
}

void NetGameOver_OnAnimate(int frame)
{
	if (frame == 0)
	{
		EnableInput(0);
		ShowScroll(uiScroll, 7);
		NextFrame(0.5);
		ShowRoundScore();
		ShowFinalScore();
	} else if (frame == 1)
	{
		Activate(uiRoundScoreboard, 1);
		NextFrame(5);
	} else if (frame == 2)
	{
		Activate(uiRoundScoreboard, 0);
		ShowScroll(uiScroll, 1);
		NextFrame(0.5);
	} else if (frame == 3)
	{
		Activate(uiFinalScoreboard, 1);
		NextFrame(3);
	} else if (frame == 4)
	{
		EnableInput(1);
	}
}

int NetGameOver_OnInput(int key)
{
	if (IsButtonA(key))
	{
		SetAppState(APPSTATE_RESTART_NET_GAME);
		return 1;
	}
	return 0;
}


/////////////// competition host win (team B leader not join)
void CompetitionHostWin_OnAnimate(int frame)
{
	AnimateDialog(uiScroll, frame);
	if (frame == 0)
	{
		if (GetPlayerSelectTeam(GetLocalPlayer()) == 1)
			Text(MSG_COMPETITION_HOST_WIN);
		else
			Text(MSG_COMPETITION_HOST_WIN_2);
	}
}

int CompetitionHostWin_OnInput(int key)
{
	return NetGameOver_OnInput(key);
}


// Training

void TrainingMenu_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 6);
		Show(0);
		EnableInput(0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		Show(1);
		EnableInput();
	}
}

int TrainingMenu_OnInput(int key)
{
	if (IsButtonUp(key))
	{
		SelectPrevSimpleItem(uiTrainingList);
		PlaySound(sndPadY);
		return 1;
	}
	else if (IsButtonDown(key))
	{
		SelectNextSimpleItem(uiTrainingList);
		PlaySound(sndPadY);
		return 1;
	}
	else if (IsButtonA(key))
	{
		Begin(uiTrainingList);
			BeginChild(GetSelectedSimpleItemIndex(uiTrainingList)); var_uiTrainingSelection = GetText(); End();
		End();
		Enable(0);
		PlaySound(sndOK);
		return 1;
	} else if (IsButtonB(key))
	{
		PlaySound(sndCancel);
		LeaveGame();
		return 1;
	}

	return 0;
};


// training success
void TrainingOver1_OnAnimate(int frame)
{
	AnimateDialog(uiScroll, frame);
}

int TrainingOver1_OnInput(int key)
{
	if (IsButtonX(key))
	{
		Begin(uiTrainingList);
			BeginChild(var_uiTrainingStage-1); var_uiTrainingSelection = GetText(); End();
		End();
		ActivateUI(0);
		return 1;
	}
	else if (IsButtonA(key))
	{
		if (var_uiTrainingStage == 5)
		{
			ActivateUI(UI2_TRAINING_MENU);
			return 1;
		}
		Begin(uiTrainingList);
			BeginChild(var_uiTrainingStage); var_uiTrainingSelection = GetText(); End();
		End();

//		ActivateUI(0);
		Enable(0);
		PlaySound(sndOK);
		return 1;
	}
	else if (IsButtonB(key))
	{
		ActivateUI(UI2_TRAINING_MENU);
		PlaySound(sndCancel);
		return 1;
	}
}

// stage 1
void TrainingOver2_OnAnimate(int frame)
{
	AnimateDialog(uiScroll, frame);
}

int TrainingOver2_OnInput(int key)
{
	if (IsButtonX(key))
	{
		Begin(uiTrainingList);
			BeginChild(var_uiTrainingStage-1); var_uiTrainingSelection = GetText(); End();
		End();
		ActivateUI(0);
		return 1;
	}
	else if (IsButtonA(key))
	{
		if (var_uiTrainingStage == 5)
		{
			var_uiTrainingSelection = "TROVER";
			GameScript("CalculateScore();");
			ActivateUI(0);
			PlaySound(sndOK);
//			PlayMusic("win");
			return 1;
		}
		Begin(uiTrainingList);
			BeginChild(var_uiTrainingStage); var_uiTrainingSelection = GetText(); End();
		End();

		ActivateUI(0);
		PlaySound(sndOK);
		return 1;
	}
	else if (IsButtonB(key))
	{
		var_uiTrainingSelection = "TROVER";
		GameScript("CalculateScore();");
		ActivateUI(0);
		PlaySound(sndOK);
//		PlayMusic("win");
		return 1;
	}
}


//////////////// receive game world data
void ReceiveGameWorld_OnAnimate(int frame)
{
	AnimateDialog(uiScroll, frame);
	if (frame == 0)
	{
		NextFrame(0.3, 1);	// show dialog after 0.3 second
	} else if (frame == 2)
	{
		if (GetSceneName()=="")
			Text(MSG_WAIT_HOST_SESSION);
		else
			Text(MSG_LOAD_SESSION_DATA);
	} else if (frame == 3)
	{
		if (GetSceneName()=="")
			Text(MSG_WAIT_HOST_SESSION);
		else
			Text(MSG_LOAD_SESSION_DATA);
		NextFrame(0.1, 3);
	}
}

int ReceiveGameWorld_OnInput(int key)
{
 	if (IsButtonB(key))
	{
		ActivateUI(UI2_CONFIRM_LEAVE_GAME);
		PlaySound(sndCancel);
		return 1;
	}

	return 0;
}

/////////// start menu
void StartMenu_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 11);
		Show(0);
		EnableInput(0);
		SelectSimpleItem(uiStartList, 0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		Show();
		EnableInput();
		BeginChild(0);
			if (var_netMode==NET_MODE_NONE || var_netMode==NET_MODE_OFFLINE)
				Text(STR_START_MENU);
			else
				Text(STR_OPTIONS_MENU);
		End();
		Begin(uiStartList);
			int x, y, c, wpn;
			BeginChild(0); Show(); x=GetX(); y=GetY(); End(); y = y + 32;	// STR_BACK_TO_GAME
			c = GetPlayerChara();
			if (c)
				wpn = GetCharaWeapon(c);
			else if (var_dedicatedServer == 0)
				wpn = var_uiWeaponSelection;
			else
				wpn = 0;
			if (wpn)
			{
				BeginChild(1); Show(); Position(x, y); End(); y = y + 32;	// STR_COMBO_TABLE
			} else
			{
				ShowChild(1, 0);
			}
			if (IsServer() && !IsCompetitionSession() && (var_netMode==NET_MODE_LAN || var_netMode==NET_MODE_INTERNET))
			{
				BeginChild(2); Show(); Position(x, y); End(); y = y + 32;	// STR_COMBO_TABLE
			} else
			{
				ShowChild(2, 0);
			}
			BeginChild(3); Show(1); Position(x, y); End(); y = y + 32;	// STR_START_MENU_SETTINGS
			BeginChild(4); 												// STR_START_MENU_LIVE_SETTINGS
				Show(); Position(x, y);
				ShowLiveNotification(GetChild(2));
			End(); y = y + 32;
			BeginChild(5); Show(1); Position(x, y); End(); y = y + 32;	// STR_QUIT_GAME
		End();
		NextFrame(0.2, 1);		// check live notification again
	}
}

int StartMenu_OnInput(int key)
{
	if (IsButtonUp(key))
	{
		SelectPrevSimpleItem(uiStartList);
		PlaySound(sndPadY);
		return 1;
	}
	else if (IsButtonDown(key))
	{
		SelectNextSimpleItem(uiStartList);
		PlaySound(sndPadY);
		return 1;
	}
	else if (IsButtonA(key))
	{
		int textID = GetSelectedSimpleItemText(uiStartList);
		if (textID == STR_BACK_TO_GAME)
		{
			ActivateUI(UI2_PLAY_GAME);
			return 1;
		} else if (textID == STR_COMBO_TABLE)
		{
			ActivateUI(UI2_COMBO_TABLE);
		} else if (textID == STR_KICK_PLAYER)
		{
			ActivateUI(UI2_KICK_MENU);
		} else if (textID == STR_START_MENU_SETTINGS)
		{
			ActivateUI(UI2_SETTING_MENU);
		} else if (textID == STR_START_MENU_LIVE_SETTINGS)
		{
			ActivateUI(UI2_SETTING_LIVE);
		} else if (textID == STR_QUIT_GAME)
		{
			ActivateUI(UI2_CONFIRM_LEAVE_GAME);
		}
		PlaySound(sndOK);
		return 1;
	}
	else if (IsButtonB(key) || IsButtonSTART(key))
	{
		// back to game
		ActivateUI(UI2_PLAY_GAME);
		return 1;
	}

	return 0;
};

//////////// in game score borad
void ShowInGameScore()
{
	BeginChild(2);		// title
		Text(var_rule+STR_SCORE_TITLE_BEGIN);
	End();

	Begin(uiInGameScoreList);
	int i, j, c, team, useTeam;

	for (i=0; i<16; i++)
	{
		BeginChild(i);
			BeginChild(0); TextColor(0,0,0,0); End();
			BeginChild(1); TextColor(0,0,0,0); End();
			BeginChild(2); TextColor(0,0,0,0); End();
			BeginChild(3); Color(0,0,0,0,0); End();
		End();
	}

	int n = GetNumCharas();
	if (n > 16)
		n = 16;

	int t, t1, t2;
	t = t1 = t2 = 0;
	float r,g,b;
	int me = GetPlayerChara();
	int stampX, stampY;
	useTeam = IsFairTeamRule();

	int scoreIdx = 0;
	if (var_rule==RULE_VIP)
		scoreIdx = 2;
	else if (var_rule==RULE_GIANT_KILL)
		scoreIdx = 1;

	for (i=0; i<n; i++)
	{
		c = GetChara(i);
		if (c == 0)
			continue;
		team = GetCharaAttrib(c, CHARA_TEAM);
		if (team==1)
		{
			r = teamColorR[1]; g = teamColorG[1]; b = teamColorB[1];
			t = t1;
			t1++;
		} else if (team==2)
		{
			r = teamColorR[2]; g = teamColorG[2]; b = teamColorB[2];
			if (useTeam)
			{
				t = t2+8;
				t2++;
			} else
			{
				t = t1;
				t1++;
			}
		} else
		{
			r = teamColorR[0]; g = teamColorG[0]; b = teamColorB[0];
			t = t1;
			t1++;
		}
		BeginChild(t);
			BeginChild(0); TextColor(r,g,b); Text(GetCharaDisplayName(c)); End();
			BeginChild(1); TextColor(r,g,b); Number(GetCharaScore(c, scoreIdx)); End();
			BeginChild(2); TextColor(r,g,b); Number(GetCharaScore(c, scoreIdx)+GetCharaTotalScore(c, scoreIdx)); End();
			BeginChild(3);
				Color(r,g,b);
				if (IsCharaVIP(c) || IsCharaGiant(c))
					Image(iconVIP);
				else if (IsCharaDead(c))
					Image(iconDead);
				else
					Color(0,0,0,0);
			End();
			if (c == me)
			{
				stampX = GetX();
				stampY = GetY();
			}
		End();
	}
	End();

	BeginChild(4);		// arrow
		if (me != 0)
		{
			Show();
			Position(stampX-5, stampY-2);
		} else
			Show(0);
	End();

	if (var_rule==RULE_TEAM_DEATH_MATCH || var_rule==RULE_CUSTOM2)
	{
		ComputeTeamScore();
		ShowTeamScore(GetChild(6), GetChild(7), g_team1Score, g_team2Score);
	}
	else
	{
		ShowChild(6, 0);
		ShowChild(7, 0);
	}
}

void InGameScoreboard_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 9);
		Show(0);
		NextFrame(0.1);
		ShowInGameScore();
	} else if (frame == 1)
	{
		Show();
		NextFrame(0.1);
	} else if (frame == 2)
	{
		ShowInGameScore();
		NextFrame(0.2, 2);
	}
}

////////////// mission objective
void MissionObjective_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 10);
		Show(0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		Show();
		Begin(uiMissionObjectiveList);
			int x = 150;
			int y = 180;
			for (int i=0; i<10; i++)
			{
				BeginChild(i);
					Position(x, y);
					if (GetMissionObjectiveSwitch(i))
						TextColor(0,0,0);
					else
						TextColor(0,0,0, 0.3);
					wstring txt = GetWStringFromTable(GetMissionObjectiveText(i), 1);		// use string table 1
					Text(txt);
					y = y + CountTextLines(txt) * 25 + 5;
				End();
			}
		End();
	}
}

////////////// confirm leave game
void ConfirmLeaveGame_OnAnimate(int frame)
{
	AnimateDialog(uiScroll, frame);
	if (frame == 0)
	{
		if (var_netMode == NET_MODE_NONE)
		{
			if (var_uiMissionSelection == "TRAINING")
				Text(MSG_REALLY_LEAVE_TRAINING);
			else
				Text(MSG_REALLY_LEAVE_GAME);
		} else if (var_netMode == NET_MODE_OFFLINE)
		{
			Text(MSG_REALLY_LEAVE_OFFLINE_GAME);
		} else
		{
			if (IsServer())
				Text(MSG_REALLY_LEAVE_SERVER);
			else
			{
				if (var_netMode == NET_MODE_INTERNET)
					Text(MSG_REALLY_LEAVE_INTERNET);
				else
					Text(MSG_REALLY_LEAVE_LAN);
			}
		}
	}
}

int ConfirmLeaveGame_OnInput(int key)
{
	if (IsButtonA(key))
	{
		if (IsCompetitionSession() && IsServer() && GetAppState()==APPSTATE_PLAY_GAME)
			CompetitionResult(0);			// close competition before game over
		PlaySound(sndOK);
		LeaveGame();
		return 1;
	} else if (IsButtonB(key))
	{
		ActivateUI(g_lastActiveUI);
		PlaySound(sndCancel);
		return 1;
	}

	return 0;
}

////////////// confirm leave current game and join other game
int ConfirmJoinOtherGame_OnInput(int key)
{
	if (IsButtonA(key))
	{
		SetAppState(APPSTATE_CONNECT_INTERNET);
		PlaySound(sndOK);
		return 1;
	} else if (IsButtonB(key))
	{
		CancelJoinOtherSession();
		ActivateUI(UI2_PLAY_GAME);
		PlaySound(sndCancel);
		return 1;
	}

	return 0;
}

/////////////// session not compatible
void SessionNotCompatible_OnAnimate(int frame)
{
	AnimateDialog(uiScroll, frame);
}

int SessionNotCompatible_OnInput(int key)
{
	if (IsButtonB(key))
	{
		ActivateUI(UI2_PLAY_GAME);
		PlaySound(sndCancel);
		return 1;
	}
	return 0;
}

/////////// setting menu
void SettingMenu_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 6);
		Show(0);
		EnableInput(0);
		NextFrame(0.1);
		
		ShowUI(uiShowPlayerName, var_rule!=RULE_SCENARIO);
		g_settingSelection = SelectOption(uiSettingList, 0);
	} else if (frame == 1)
	{
		Show();
		EnableInput();
	}
}

int SettingMenu_OnInput(int key)
{
	if (IsButtonUp(key))
	{
		g_settingSelection = SelectPrevOption(uiSettingList);
		PlaySound(sndPadY);
		return 1;
	}
	else if (IsButtonDown(key))
	{
		g_settingSelection = SelectNextOption(uiSettingList);
		PlaySound(sndPadY);
		return 1;
	} else if (IsButtonLeft(key) || IsButtonRight(key))
	{
		if (IsButtonLeft(key))
			SelectOptionListItem(uiSettingList, g_settingSelection, -1);
		else
			SelectOptionListItem(uiSettingList, g_settingSelection, 1);

		Begin(uiSettingList); BeginChild(g_settingSelection);
			int textID = GetTextID(); int value = GetSelectedOptionItemValue(GetID());
		End(); End();
		if (textID == STR_MUSIC_VOLUME)
		{
			var_stMusicVolume = value;
			SetMusicVolume(value * 0.01);
		} else if (textID == STR_EFFECTS_VOLUME)
		{
			var_stEffectsVolume = value;
			SetSoundVolume(value * 0.01);
			Set3DSoundVolume(value * 0.01);
		} else if (textID == STR_VOICE_VOLUME)
		{
			var_stVoiceVolume = value;
			SetVoiceVolume(value * 0.01);
			SetMovieVolume(value * 0.01);		///???
			PlayVoice(sndVoiceVolume);
		} else if (textID == STR_VIDEO_GAMMA)
		{
			var_stVideoGamma = value;
			GammaCorrection(var_stVideoContrast*0.01, var_stVideoBrightness*0.01, var_stVideoGamma*0.01);
		} else if (textID == STR_VIDEO_BRIGHTNESS)
		{
			var_stVideoBrightness = value;
			GammaCorrection(var_stVideoContrast*0.01, var_stVideoBrightness*0.01, var_stVideoGamma*0.01);
		} else if (textID == STR_VIDEO_CONTRAST)
		{
			var_stVideoContrast = value;
			GammaCorrection(var_stVideoContrast*0.01, var_stVideoBrightness*0.01, var_stVideoGamma*0.01);
		} else if (textID == STR_VIBRATION)
		{
			var_stControllerVibration = value;
			if (value)
				TestRumble(MOTOR_BOTH, RUMBLE_FLAT, 0.2, 0.5, 0.5);
		} else if (textID == STR_CAMERA_INVERT)
		{
			var_stCameraInvert = value;
		} else if (textID == STR_DISPLAY_PLAYER_NAME)
		{
			var_stShowPlayerName = value;
		}

		PlaySound(sndPadX);
		return 1;
	} else if (IsButtonY(key))
	{
		// default settings
		var_stMusicVolume = 100;
		SetMusicVolume(1);
		var_stEffectsVolume = 100;
		SetSoundVolume(1);
		Set3DSoundVolume(1);
		var_stVoiceVolume = 100;
		SetVoiceVolume(1);
		SetMovieVolume(1);	///???
		SelectOptionItemValue(uiMusicVolumeOption, var_stMusicVolume);
		SelectOptionItemValue(uiEffectsVolumeOption, var_stEffectsVolume);
		SelectOptionItemValue(uiVoiceVolumeOption, var_stVoiceVolume);

		var_stVideoBrightness = 0;
		var_stVideoContrast = 0;
		var_stVideoGamma = 100;
		GammaCorrection(0, 0, 1);
		SelectOptionItemValue(uiVideoGammaOption, var_stVideoGamma);
		SelectOptionItemValue(uiVideoBrightnessOption, var_stVideoBrightness);
		SelectOptionItemValue(uiVideoContrastOption, var_stVideoContrast);

		var_stControllerVibration = 1;
		var_stCameraInvert = 0;
		SelectOptionItemValue(uiControllerVibrationOption, var_stControllerVibration);
		SelectOptionItemValue(uiCameraInvertOption, var_stCameraInvert);
		
		var_stShowPlayerName = 1;
		SelectOptionItemValue(uiShowPlayerName, var_stShowPlayerName);

		PlaySound(sndPadX);
		return 1;
	} else if (IsButtonB(key))
	{
		SaveSettings();
		ActivateUI(UI2_START_MENU);
		PlaySound(sndCancel);
		return 1;
	}
}


//////////////// setting live
void ShowLiveSettings()
{
	Begin(uiSettingLiveList);
		if (IsLoginLive())
		{
			ShowChild(0, 0);	// sign in
			ShowChild(1, 1);	// sign out
			BeginChild(2);		// friend list
				Show();
				ShowLiveNotification(GetChild(3));
			End();
			ShowChild(3, var_netMode==NET_MODE_INTERNET); // player list

			ShowChild(4, 1);		// appear offline
			int voiceTV;
			BeginChild(5);
				if (!IsShow())
				{
					SelectOptionItemValue(GetID(), IsVoiceThroughSpeaker());
					Show();
				}
				voiceTV=GetSelectedOptionItemValue(GetID());
			End();	// voice through speakers
			ShowChild(6, voiceTV);	// voice through speakers volume
		} else
		{
			ShowChild(0, 1);
			ShowChild(1, 0);
			ShowChild(2, 0);
			ShowChild(3, 0);
			ShowChild(4, 0);
			ShowChild(5, 0);
			ShowChild(6, 0);
		}
	End();

	if (IsLoginLive())
	{
		if (g_settingLiveSelection==0 || (g_settingLiveSelection==3 && var_netMode!=NET_MODE_INTERNET))
			g_settingLiveSelection = SelectOption(uiSettingLiveList, 1);	// sign out
	} else
	{
		if (g_settingLiveSelection != 0)
			g_settingLiveSelection = SelectOption(uiSettingLiveList, 0);		// sign in
	}

	if (var_netMode == NET_MODE_INTERNET)
	{
		// can't sign in/out if already live game
		Begin(uiSettingLiveList);
			ShowChild(0, 0);
			ShowChild(1, 0);
		End();
		if (g_settingLiveSelection==0 || g_settingLiveSelection==1)
			g_settingLiveSelection = SelectOption(uiSettingLiveList, 2);
	}

	ShowLoginState(uiLoginState2);

	BeginChild(2);		// msg bar
		if (g_settingLiveSelection <= 3)
			Text(BUT_CONFIRM_SWITCH_BACK2);
		else
			Text(BUT_SWITCH_CHANGE_BACK2);
	End();
}

void SettingLiveMenu_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 6);
		Show(0);
		EnableInput(0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		Show();
		EnableInput();
		ShowLiveSettings();
		NextFrame(0.1, 2);
	} else if (frame == 2)
	{
		ShowLiveSettings();
		NextFrame(0.1, 2);		// check login status again
	}
}

int SettingLiveMenu_OnInput(int key)
{
	int textID, value;
	if (IsButtonUp(key))
	{
		g_settingLiveSelection = SelectPrevOption(uiSettingLiveList);
		ShowLiveSettings();
		PlaySound(sndPadY);
		return 1;
	}
	else if (IsButtonDown(key))
	{
		g_settingLiveSelection = SelectNextOption(uiSettingLiveList);
		ShowLiveSettings();
		PlaySound(sndPadY);
		return 1;
	} else if (IsButtonLeft(key) || IsButtonRight(key))
	{
		if (IsButtonLeft(key))
			SelectOptionListItem(uiSettingLiveList, g_settingLiveSelection, -1);
		else
			SelectOptionListItem(uiSettingLiveList, g_settingLiveSelection, 1);

		Begin(uiSettingLiveList); BeginChild(g_settingLiveSelection);
			textID = GetTextID(); value = GetSelectedOptionItemValue(GetID());
		End(); End();
 		if (textID == STR_APPEAR_OFFLINE)
		{
			var_stAppearOffline = value;
			SetOnlineStatus(!var_stAppearOffline);
			PlaySound(sndPadX);
		} else if (textID == STR_VOICE_THROUGH_SPEAKER)
		{
			SetVoiceThroughSpeaker(value);
			PlaySound(sndPadX);
		} else if (textID == STR_VOICE_SPEAKER_VOLUME)
		{
			SetVoiceThroughSpeakerVolume(value*0.01);
			PlaySound(sndPadX);
		}
		ShowLiveSettings();
		return 1;
	} else if (IsButtonA(key))
	{
		Begin(uiSettingLiveList); BeginChild(g_settingLiveSelection);
			textID = GetTextID();
		End(); End();

 		if (textID==STR_LOGIN_LIVE && !IsLoginLive())
		{
			LoginLive();
			PlaySound(sndOK);
		} else if (textID==STR_LOGOUT_LIVE && IsLoginLive())
		{
			LogoutLive();
			PlaySound(sndOK);
		} else if (textID == STR_PLAYERS_LIST)
		{
			StartPlayerListMenu();
			PlaySound(sndOK);
		} else if (textID == STR_FRIENDS_LIST)
		{
			StartFriendListMenu();
			PlaySound(sndOK);
		}
		ShowLiveSettings();
		return 1;
	} else if (IsButtonB(key))
	{
		ActivateUI(UI2_START_MENU);
		PlaySound(sndCancel);
		return 1;
	}
}


///////////////// combo table
int g_comboView = 0;
const int COMBO_ROW_MAX = 5;
void ShowComboTable()
{
	int i, s, c, wpn;
	Begin(uiComboList);	
		c = GetPlayerChara();
		if (c)
			wpn = GetCharaWeapon(c) / 10;
		else
			wpn = var_uiWeaponSelection / 10;			
		s = GetNumComboText(wpn);
		if (g_comboView < 0)
			g_comboView = 0;
		if (g_comboView > s-COMBO_ROW_MAX)
			g_comboView = s-COMBO_ROW_MAX;
		for (i=0; i<COMBO_ROW_MAX; i++)
		{
			int n = g_comboView + i;
			wstring name, cmd;
			GetComboText(wpn, n, name, cmd);
			BeginChild(i*2); Text(name); End();
			BeginChild(i*2+1); Text(cmd); End();
		}
	End();

	ShowChild(3, g_comboView>0);		// up arrow
	ShowChild(4, g_comboView<s-COMBO_ROW_MAX);		// down arrow
}

void ComboTable_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 6);
		Show(0);
		ShowComboTable();
		EnableInput(0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		Show();
		EnableInput();
	}
}

int ComboTable_OnInput(int key)
{
	if (IsButtonUp(key))
	{
		g_comboView--;
		ShowComboTable();
		PlaySound(sndPadX);
		return 1;
	} else if (IsButtonDown(key))
	{
		g_comboView++;
		ShowComboTable();
		PlaySound(sndPadX);
		return 1;
	} else if (IsButtonB(key))
	{
		ActivateUI(UI2_START_MENU);
		PlaySound(sndCancel);
		return 1;
	}
	return 0;
}


///////////// kick menu
int g_numKickList = 0;
void ShowKickList()
{
	Begin(uiKickList);
	int i, s, p;
	for (i=0; i<16; i++)
	{
		BeginChild(i); Show(0); SetSimpleItemTextW(GetID(), L""); Number(-1); End();
	}

	g_numKickList = 0;
	s = GetNumPlayers();
	if (s > 16)
		s = 16;
	s = 14;
	for (i=0; i<s; i++)
	{
		p = GetPlayer(i);
		if (p == 0)
			continue;
		if (GetOwnerID(p) < 0)		// can't kick server player
			continue;

		BeginChild(g_numKickList);
			Show();
			Number(p);
			SetSimpleItemTextW(GetID(), GetPlayerDisplayName(p));
		End();
		g_numKickList++;
	}
	End();

	g_kickSelection = 0;
	SelectSimpleItem(uiKickList, 0);
}


void KickMenu_OnAnimate(int frame)
{
	if (frame == 0)
	{
		ShowScroll(uiScroll, 9);
		Show(0);
		ShowKickList();
		EnableInput(0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		Show();
		EnableInput();
	}
}

int KickMenu_OnInput(int key)
{
	int row = 8;
	if (IsButtonUp(key))
	{
		g_kickSelection = GetUpIndex(g_kickSelection, g_numKickList, row);
		SelectSimpleItem(uiKickList, g_kickSelection);
		PlaySound(sndPadY);
	} else if (IsButtonDown(key))
	{
		g_kickSelection = GetDownIndex(g_kickSelection, g_numKickList, row);
		SelectSimpleItem(uiKickList, g_kickSelection);
		PlaySound(sndPadY);
	} else if (IsButtonLeft(key) || IsButtonRight(key))
	{
		g_kickSelection = GetLeftIndex(g_kickSelection, g_numKickList, row);
		SelectSimpleItem(uiKickList, g_kickSelection);
		PlaySound(sndPadY);
	} else if (IsButtonA(key))
	{
		if (g_numKickList > 0)
		{
			Begin(uiKickList); BeginChild(g_kickSelection); g_kickPlayerID=GetNumber(); End(); End();
			ActivateUI(UI2_CONFIRM_KICK);
			PlaySound(sndOK);
		}
	} else if (IsButtonB(key))
	{
		ActivateUI(UI2_START_MENU);
		PlaySound(sndCancel);
	}
}


////////////// confirm kick player
void ConfirmKick_OnAnimate(int frame)
{
	AnimateDialog(uiScroll, frame);
	if (frame == 0)
		Text(GetWStringFromTable(MSG_CONFIRM_KICK)+GetPlayerDisplayName(g_kickPlayerID)+GetWStringFromTable(MSG_CONFIRM_KICK_));
}

int ConfirmKick_OnInput(int key)
{
	if (IsButtonA(key))
	{
		KickOutPlayer(g_kickPlayerID);
		ActivateUI(UI2_KICK_MENU);
		PlaySound(sndOK);
		return 1;
	} else if (IsButtonB(key))
	{
		ActivateUI(UI2_KICK_MENU);
		PlaySound(sndCancel);
		return 1;
	}
	return 0;
}

//////////// auto demo
int AutoDemo_OnInput(int key)
{
	if (IsButtonA(key) || IsButtonSTART(key))
	{
		GameOver();
		return 1;
	}

	return 0;
}


//////////// credit
int Credit_OnInput(int key)
{
	if (IsButtonA(key) || IsButtonSTART(key))
	{
		GameOver();
		return 1;
	}

	return 0;
}

int g_creditLine;
void Credit_OnAnimate(int frame)
{
	if (frame == 0)
	{
		g_creditLine = 0;
		ShowChild(0, 0);
		NextFrame(0.1);
	} else if (frame == 1)
	{
		float speed = 1;
		int i,n;
		BeginChild(0);
			Show();
			TweenPosition(230, 0, 230, -30, speed);
			n = NumChildren();
			for (i=0; i<n; i++)
			{
				BeginChild(i);
					wstring line = GetWStringFromTable(i+g_creditLine, 1);
					wstring style = subwcs(line, 0, 1);
					wstring txt;
					if (style == L"1")
					{
						TextFlag(TEXT_ALIGN_CENTER | TEXT_ITALIC);
						txt = subwcs(line, 2, wcslen(line)-2);
						TextColor(1,1,1);
					}
					else
					{
						TextFlag(TEXT_ALIGN_CENTER);
						txt = line;
						TextColor(1,1,1,0.8);
					}
					Text(txt);	// read from level string table
				End();
			}
		End();
		if (GetWStringFromTable(n+g_creditLine, 1) == L"_END_")
			g_creditLine = 0;
		else
			g_creditLine++;
		NextFrame(speed, 1);
	}
}

//////////// dedicated server
int DedicatedServer_OnInput(int key)
{
	if (IsButtonX(key))
	{
		SetCameraMode(0);
		PlaySound(sndSel);
	} else if (IsButtonY(key))
	{
		SetCameraMode(1);
		SetCameraNextTarget();
		PlaySound(sndSel);
	}

	return 0;
}

void DedicatedServer_OnAnimate(int frame)
{
	if (frame==0)
	{
		TextColor(1,1,1,1);
		NextFrame(0.01);
	} else if (frame==1)
	{
		NextFrame(0.4);
	} else if (frame==2)
	{
		TweenTextColor(1,1,1,1, 1,1,1,0);
		NextFrame(0.2);
	} else if (frame==3)
	{
		TweenTextColor(1,1,1,0, 1,1,1,1);
		NextFrame(0.2, 1);
	}
}

void OnDefineUI()
{
	int x, y, i;

	iconDead = CreateImage("radar_dead");
	iconVIP = CreateImage("radar_vip");
	iconFriendRequest = CreateImage("icon_friendrequest");
	iconGameInvite = CreateImage("icon_gameinvite");

	uiRoot = GetID();

	Begin(uiBackground=NewUI());
		Color(0,0,0,0.8); Size(800, 600);
	End();

	uiScroll = NewScroll2();
	uiScroll2 = NewTopScroll2();

	Begin(uiSpectatorMenu=NewUI("SpectatorMenu"));
		Begin(NewUI());
			Position(75,180); Size(650, 20); Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(75,470); Size(650, 15); Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(400, 180);
			Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER); Text(STR_SCORE_TITLE_BEGIN);
		End();

		Begin(uiInGamePlayers=NewUI());
			for(i=0; i<16; i++)
			{
				Begin(NewUI());
					if (i < 8)
						Position(110, 220+i*30);
					else
						Position(390, 220+(i-8)*30);
					Image("brush2"); Color(1,1,1); Size(310, 20);

					Begin(NewUI());	// name
						Position(90, 2);
						Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X);
					End();

					Begin(NewUI());	// score
						Position(190, 2);
						Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X); ShowNumber(0);
					End();

					Begin(NewUI()); // total score
						Position(240, 2);
						Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X); ShowNumber(0);
					End();
				End();
			}
		End();

		Begin(NewUI());
			Font(1); TextColor(1,1,1); TextSize(25); Text(STR_ARROW); TextFlag(TEXT_SHADOW);
			EventHandler("OnAnimate", "FlashArrow"); PlayAnimation();
		End();

		NewCaption2(STR_SCORE_BOARD);

		Begin(NewUI());
			Position(600, 100);
			Font(1); TextSize(25); Text(STR_SPECTATOR); TextFlag(TEXT_SHADOW); TextColor(1,1,1);
			EventHandler("OnAnimate", "FlashArrow"); PlayAnimation();
		End();
		Begin(NewMsgBar(BUT_SPECTATOR_FIGHT));
			Position(0, 490);
		End();

		NewUITime(400, 200, 20);
	End();

	Begin(uiFollowMenu=NewUI("FollowMenu"));
		Begin(NewMsgBar(BUT_FOLLOW_MENU));
			Position(0, 490);
		End();

		Begin(NewUI());
			Position(600, 100);
			Font(1); TextSize(25); Text(STR_SPECTATOR); TextFlag(TEXT_SHADOW); TextColor(1,1,1); PlayAnimation();
			EventHandler("OnAnimate", "FlashArrow"); PlayAnimation();
		End();
	End();

	Begin(uiGameOver=NewUI("GameOver"));
		Begin(NewUI());
			Position(250,175); Size(130,130);
			Image("drops"); Color(0,0,0);
		End();
		Begin(NewUI());
			Position(340,175); Size(130,130);
			Image("drops3"); Color(0,0,0);
		End();
		Begin(NewUI());
			Position(430,175); Size(130,130);
			Image("drops2"); Color(0,0,0);
		End();
		Begin(NewUI());
			Position(280,310); Size(100,100);
			Image("drops3"); Color(0,0,0);
		End();
		Begin(NewUI());
			Position(420,310); Size(100,100);
			Image("drops"); Color(0,0,0); Flip(1);
		End();

		Begin(NewUI());
			Position(250, 210); Size(300, 40);
			Font(1); TextColor(1,1,1); TextSize(40); TextFlag(TEXT_ALIGN_CENTER_XY); Text(STR_GAME_OVER);
			Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(260, 340); Size(280, 30);
			Font(1); TextColor(1,1,1); TextSize(30); TextFlag(TEXT_ALIGN_CENTER_XY); Text(STR_CONTINUE_GAME);
			Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(270, 390); Size(130, 30);
			Font(1); TextColor(1,1,1); TextSize(30); TextFlag(TEXT_ALIGN_CENTER_XY); Text(BUT_A_YES);
			Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(400, 390); Size(130, 30);
			Font(1); TextColor(1,1,1); TextSize(30); TextFlag(TEXT_ALIGN_CENTER_XY); Text(BUT_B_NO);
			Image("brush2"); Color(1,1,1);
		End();
	End();
	
	uiCompetitionHostWin = NewDialog("CompetitionHostWin", MSG_COMPETITION_HOST_WIN, BUT_CONFIRM);	

	Begin(uiStageClear=NewUI("StageClear"));
		Number(0); ShowNumber(0);
		Begin(NewUI());		// 0
//			Position(65,395); Size(700, 12); Image("brush2"); Color(1,1,1); Show(1);
			Position(65,360); Size(700, 12); Image("brush2"); Color(1,1,1); Show(1);
		End();

		// kill 1
		y = 140;
		Begin(NewUI());		// 1
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_KILL1);
		End();
		Begin(NewUI());		// 2
			Position(500, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); ShowNumber(0);	// result number
		End();
		NewCounterItem(650, y); // 3

		// kill 2
		y = y + 35;
		Begin(NewUI());		// 4
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_KILL2);
		End();
		Begin(NewUI());		// 5
			Position(500, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); ShowNumber(0);	// result number
		End();
		NewCounterItem(650, y); // 6

		// combo
		y = y + 35;
		Begin(NewUI());		// 7
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_COMBO);
		End();
		Begin(NewUI());		// 8
			Position(500, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); ShowNumber(0);	// result number
		End();
		NewCounterItem(650, y); // 9

		// AI Alive
		y = y + 35;
		Begin(NewUI());		// 10
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_AI_ALIVE);
		End();
		Begin(NewUI());		// 11
			Position(500, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); ShowNumber(0);	// result number
		End();
		NewCounterItem(650, y); // 12

		// Phoenix Stone
//		y = y + 35;
		Begin(NewUI());		// 13
			Show(0);
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_PHOENIX_STONE);
		End();
		Begin(NewUI());		// 14
			Show(0);
			Position(500, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); ShowNumber(0);	// result number
		End();
		NewCounterItem(650, y); // 15

		// time
		y = y + 35;
		Begin(NewUI());		// 16
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_TIME);
		End();
		Begin(NewUI());		// 17
			Position(500, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); 	// time
		End();
		NewCounterItem(650, y); // 18

		// stage score
		y = y + 40;
		Begin(NewUI());		// 19
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_STAGE);
		End();
		NewCounterItem(650, y); // 20

		// total time
		y = y + 70;
		Begin(NewUI());		// 21
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_TOTALTIME);
		End();
		Begin(NewUI());		// 22
			Position(500, y);
			Font(1); TextColor(0,0,0); TextSize(24); TextFlag(TEXT_ALIGN_RIGHT); 	// time
		End();

		// total score
		y = y + 35;
		Begin(NewUI());		// 23
			Position(130, y);
			Font(1); TextColor(0,0,0); TextSize(24); Text(STR_SCORE_TOTAL);
		End();
		NewCounterItem(650, y); // 24

		NewCaption(STR_STAGE_CLEAR);
		NewMsgBar(BUT_SKIP);
	End();

	Begin(uiUnlock=NewUI("Unlock"));
		Size(800, 600); Layer(30);
		Color(0,0,0,0.6);

		Begin(NewUI()); // background
			Position(200, 190); Image("scrollback_square"); Color(1,1,1); Size(400, 200);
		End();
		Begin(NewUI()); // unlock what feature
			Position(400, 250);
			Font(1); TextColor(0,0,0); TextSize(28); TextFlag(TEXT_ALIGN_CENTER_XY);
		End();
		Begin(NewUI()); // unlock what content
			Position(400, 300);
			Font(1); TextColor(0.7,0,0); TextSize(24); TextFlag(TEXT_ALIGN_CENTER_XY);
		End();
		Begin(NewUI());
			Position(185, 175); Image("scroller_left"); Size(40, 230); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(565, 175); Image("scroller_left"); Size(40, 230); Color(1,1,1);
		End();
		Begin(NewMsgBar3(BUT_CONFIRM)); Layer(30); End();
	End();

	Begin(uiRoundScoreboard=NewUI());
		NewCaption(STR_ROUND_OVER);
		Begin(NewUI());
			Position(0, 120); Size(800, 20);
			Image("brush2"); Color(1,1,1);
		End();
		Begin(uiRoundScoreListTitle=NewUI());
			Begin(NewUI());
				Position(100, 120); Size(50, 25);
				Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); Text(STR_RANK);
			End();
			Begin(NewUI());
				Position(150, 120); Size(150, 25);
				Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); Text(STR_NAME);
			End();
			Begin(NewUI());
				Position(300, 120); Size(100, 25);
				Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); Text(STR_KILL);
			End();
			Begin(NewUI());
				Position(400, 120); Size(100, 25);
				Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); Text(STR_KILL);
			End();
			Begin(NewUI());
				Position(500, 120); Size(100, 25);
				Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); Text(STR_DEATH);
			End();
			Begin(NewUI());
				Position(600, 120); Size(100, 25);
				Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); Text(STR_SCORE);
			End();
		End();


		Begin(uiRoundScoreList=NewUI());
		for(i=0; i<16; i++)
		{
			Begin(NewUI());
				Position(00, 145+i*25); Size(800, 20);
				Image("brush2"); Color(1,1,1);

				Begin(NewUI());
					Position(100, 0); Size(50, 25);
					Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); ShowNumber(0);
				End();

				Begin(NewUI());
					Position(150, 0); Size(150, 25);
					Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER);
				End();

				Begin(NewUI());
					Position(300, 0); Size(100, 25);
					Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); ShowNumber(0);
				End();

				Begin(NewUI());
					Position(400, 0); Size(100, 25);
					Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); ShowNumber(0);
				End();

				Begin(NewUI());
					Position(500, 0); Size(100, 25);
					Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); ShowNumber(0);
				End();

				Begin(NewUI());
					Position(600, 0); Size(100, 25);
					Font(1); TextColor(1,1,1); TextSize(20); TextFlag(TEXT_ALIGN_CENTER); ShowNumber(0);
				End();

			End();
		}
		End();

		Begin(NewUI());
			Font(1); TextSize(25); TextColor(1,1,1); Text(STR_ARROW2); TextFlag(TEXT_SHADOW);
			EventHandler("OnAnimate", "FlashArrow"); PlayAnimation();
		End();
		// team score
		Begin(NewUI());
			Position(270, 75);
			Font(1); TextFlag(TEXT_ALIGN_CENTER_X | TEXT_SHADOW); TextColor(1,1,1); TextSize(32); Layer(10);
		End();
		Begin(NewUI());
			Position(530, 75);
			Font(1); TextFlag(TEXT_ALIGN_CENTER_X | TEXT_SHADOW); TextColor(1,1,1); TextSize(32); Layer(10);
		End();
	End();


	Begin(uiFinalScoreboard=NewUI());

		Begin(NewUI());
			Position(75,330); Size(650, 20); Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(400, 330);
			Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER); Text(STR_SCORE_TITLE_FINAL);
		End();

		Begin(NewCaption(STR_FINAL_TOTAL_SCORE));
			Position(GetX(), 270);
		End();
		NewCaption(STR_FINAL_TEAM_SCORE);

		Begin(uiFinalScoreList=NewUI());
		for(i=0; i<16; i++)
		{
			Begin(NewUI());
				if (i < 8)
					Position(110, 350+i*22);
				else
					Position(390, 350+(i-8)*22);
				Image("brush2"); Color(1,1,1); Size(310, 20);
				Begin(NewUI());	// name
					Position(100, 2);
					Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X);
				End();
				Begin(NewUI());	// score
					Position(220, 2);
					Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X); ShowNumber(0);
				End();
			End();
		}
		End();

		Begin(NewUI());
			Font(1); TextColor(1,1,1); TextSize(25); Text(STR_ARROW3); TextFlag(TEXT_SHADOW);
			EventHandler("OnAnimate", "FlashArrow"); PlayAnimation();
		End();

		// team1 win rounds
		Begin(NewUI());
			Position(270, 75); Layer(10);
			Font(1); TextColor(teamColorR[1],teamColorG[1],teamColorB[1]); TextSize(32); TextFlag(TEXT_ALIGN_CENTER | TEXT_SHADOW); ShowNumber(0);
		End();

		// team2 win rounds
		Begin(NewUI());
			Position(530, 75); Layer(10);
			Font(1); TextColor(teamColorR[2],teamColorG[2],teamColorB[2]); TextSize(32); TextFlag(TEXT_ALIGN_CENTER | TEXT_SHADOW); ShowNumber(0);
		End();

		// team1 total final score
		Begin(NewUI());
			Position(270, 280); Layer(10);
			Font(1); TextColor(teamColorR[1],teamColorG[1],teamColorB[1]); TextSize(30); TextFlag(TEXT_ALIGN_CENTER | TEXT_SHADOW); ShowNumber(0);
		End();

		// team2 total final score
		Begin(NewUI());
			Position(530, 280); Layer(10);
			Font(1); TextColor(teamColorR[2],teamColorG[2],teamColorB[2]); TextSize(30); TextFlag(TEXT_ALIGN_CENTER | TEXT_SHADOW); ShowNumber(0);
		End();

		// who wins
		Begin(NewUI());
			Position(400, 170);
			Font(1); TextColor(1,1,1); TextSize(32); TextFlag(TEXT_ALIGN_CENTER | TEXT_SHADOW);
		End();
	End();

	Begin(uiNetRoundOver=NewUI("NetRoundOver"));
	End();

	Begin(uiNetGameOver=NewUI("NetGameOver"));
	End();

	Begin(uiInGameScoreboard=NewUI("InGameScoreboard"));

		Begin(NewUI());
			Position(75,180); Size(650, 20); Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(75,470); Size(650, 15); Image("brush2"); Color(1,1,1);
		End();
		Begin(NewUI());
			Position(400, 180);
			Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER); Text(STR_SCORE_TITLE_BEGIN);
		End();

		Begin(uiInGameScoreList=NewUI());
		for(i=0; i<16; i++)
		{
			Begin(NewUI());
				if (i < 8)
					Position(110, 220+i*30);
				else
					Position(390, 220+(i-8)*30);
				Image("brush2"); Color(1,1,1); Size(310, 20);

				Begin(NewUI());	// name
					Position(90, 2);
					Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X);
				End();

				Begin(NewUI());	// score
					Position(190, 2);
					Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X); ShowNumber(0);
				End();

				Begin(NewUI()); // total score
					Position(240, 2);
					Font(1); TextColor(1,1,1); TextSize(18); TextFlag(TEXT_ALIGN_CENTER_X); ShowNumber(0);
				End();
				Begin(NewUI());	// vip icon
					Position(260, 2); Size(18,18);
				End();
			End();
		}
		End();

		Begin(NewUI());
			Font(1); TextColor(1,1,1); TextSize(25); Text(STR_ARROW); TextFlag(TEXT_SHADOW);
			EventHandler("OnAnimate", "FlashArrow"); PlayAnimation();
		End();
		NewCaption2(STR_SCORE_BOARD);

		// team score
		Begin(NewUI());
			Position(270, 132); Layer(10);
			Font(1); TextFlag(TEXT_ALIGN_CENTER_X | TEXT_SHADOW); TextColor(1,1,1); TextSize(28);
		End();
		Begin(NewUI());
			Position(530, 132); Layer(10);
			Font(1); TextFlag(TEXT_ALIGN_CENTER_X | TEXT_SHADOW); TextColor(1,1,1); TextSize(28);
		End();
	End();


	Begin(uiMissionObjective=NewUI("MissionObjective"));
		Begin(uiMissionObjectiveList=NewUI());
			for (i=0; i<10; i++)
			{
				Begin(NewUI());
					Font(1); TextSize(20); TextColor(0,0,0); TextFlag(TEXT_MULTILINES);
				End();
			}
		End();
		NewCaption2(STR_MISSION_OBJECTIVE);
	End();


	// Training
	Begin(uiTrainingMenu=NewUI("TrainingMenu"));
		Begin(uiTrainingList=NewUI());
			x=400; y=210;
			Begin(NewSimpleItem(x, y, NAME_TR01, 22, 230)); Text("TR01"); End(); y=y+40;
			Begin(NewSimpleItem(x, y, NAME_TR02, 22, 230)); Text("TR02"); End(); y=y+40;
			Begin(NewSimpleItem(x, y, NAME_TR03, 22, 230)); Text("TR03"); End(); y=y+40;
			Begin(NewSimpleItem(x, y, NAME_TR04, 22, 230)); Text("TR04"); End(); y=y+40;
			Begin(NewSimpleItem(x, y, NAME_TR05, 22, 230)); Text("TR05"); End(); y=y+40;
		End();

		NewCaption2(STR_TRAINING_SELECT);
		NewMsgBar2(BUT_CONFIRM_SWITCH_BACK2);
	End();
	SelectSimpleItem(uiTrainingList, 0);

	Begin(uiTrainingOver1=NewDialog("TrainingOver1", STR_TRAINING_OVER, BUT_TRAINING_MENU1));
		TextSize(30);
	End();

	Begin(uiTrainingOver2=NewDialog("TrainingOver2", STR_TRAINING_OVER, BUT_TRAINING_MENU2));
		TextSize(30);
	End();

	Begin(uiReceiveGameWorld=NewDialog("ReceiveGameWorld", MSG_LOAD_SESSION_DATA, BUT_LEAVE_GAME));
		Begin(NewUI());
			Position(700, 500); Size(40*WIDTH_RATIO, 40); AbsCoord();
			Image("logo"); Color(1,1,1);
		End();
	End();

	Begin(uiStartMenu=NewUI("StartMenu"));

		Begin(NewUI());
			Position(280, 165); Size(240, 34);
			Image("brush_big"); Color(0,0,0);
			Font(1); TextColor(1,1,1); TextSize(25); TextFlag(TEXT_ALIGN_CENTER_XY); Text(STR_START_MENU);
		End();

		Begin(uiStartList=NewUI());
			Begin(NewSimpleItem(400, 215, STR_BACK_TO_GAME, 22, 230)); End();
			Begin(NewSimpleItem(400, 0, STR_COMBO_TABLE, 22, 230)); End();
			Begin(NewSimpleItem(400, 0, STR_KICK_PLAYER, 22, 230)); End();
			Begin(NewSimpleItem(400, 0, STR_START_MENU_SETTINGS, 22, 230)); End();
			Begin(NewSimpleItem(400, 0, STR_START_MENU_LIVE_SETTINGS, 22, 230));
				Begin(NewUI()); Position(190, -2); Size(30,30); Color(1,1,1); End(); 	// notification icon
			End();
			Begin(NewSimpleItem(400, 0, STR_QUIT_GAME, 22, 230)); End();
		End();

		Begin(NewMsgBar(BUT_CONFIRM_SWITCH));
			Position(0, 420); Size(800, 20); TextSize(20);
		End();
	End();
	SelectSimpleItem(uiStartList, 0);

	uiConfirmLeaveGame = NewDialog("ConfirmLeaveGame", -1, BUT_YES_NO);

	Begin(uiConfirmJoinOtherGame=NewDialog("ConfirmJoinOtherGame", -1, BUT_YES_NO));
		EventHandler("OnAnimate", "ConfirmLeaveGame_OnAnimate");
	End();

	uiSessionNotCompatible = NewDialog("SessionNotCompatible", MSG_SESSION_NOT_COMPATIBLE, BUT_BACK);

	Begin(uiSettingMenu=NewUI("SettingMenu"));
		x=190; y=180;
		Begin(uiSettingList=NewUI());

			Begin(uiMusicVolumeOption=NewOption2(x, y, STR_MUSIC_VOLUME)); y=y+30;
				BeginChild(2);
				for (i=0; i<=10; i++)
					NewOptionItemStr2(NumToStr(i), i*10);
				End();
				SelectOptionItem(GetID(), 10);
			End();
			Begin(uiEffectsVolumeOption=NewOption2(x, y, STR_EFFECTS_VOLUME)); y=y+30;
				BeginChild(2);
				for (i=0; i<=10; i++)
					NewOptionItemStr2(NumToStr(i), i*10);
				End();
				SelectOptionItem(GetID(), 10);
			End();

			if (var_demoVersion == 0)
			{
			Begin(uiVoiceVolumeOption=NewOption2(x, y, STR_VOICE_VOLUME)); y=y+30;
				BeginChild(2);
				for (i=0; i<=10; i++)
					NewOptionItemStr2(NumToStr(i), i*10);
				End();
				SelectOptionItem(GetID(), 10);
			End();
			}

			y=y+10;
			Begin(uiVideoGammaOption=NewOption2(x, y, STR_VIDEO_GAMMA)); y=y+30;
				BeginChild(2);
				for (i=5; i<=20; i++)
					NewOptionItemStr2(NumToStr("%.1f", i*0.1), i*10);
				End();
				SelectOptionItem(GetID(), 5);
			End();
			Begin(uiVideoBrightnessOption=NewOption2(x, y, STR_VIDEO_BRIGHTNESS)); y=y+30;
				BeginChild(2);
				for (i=-10; i<=10; i++)
					NewOptionItemStr2(NumToStr(i), i*2);
				End();
				SelectOptionItem(GetID(), 10);
			End();
			Begin(uiVideoContrastOption=NewOption2(x, y, STR_VIDEO_CONTRAST)); y=y+30;
				BeginChild(2);
				for (i=-10; i<=10; i++)
					NewOptionItemStr2(NumToStr(i), i*4);
				End();
				SelectOptionItem(GetID(), 10);
			End();

			y=y+10;
			Begin(uiControllerVibrationOption=NewOption(x, y, STR_VIBRATION)); y=y+30;
				BeginChild(2);
				NewOptionItem(STR_OFF, 0);
				NewOptionItem(STR_ON, 1);
				End();
				SelectOptionItem(GetID(), 0);
			End();
			Begin(uiCameraInvertOption=NewOption(x, y, STR_CAMERA_INVERT)); y=y+30;
				BeginChild(2);
				NewOptionItem(STR_OFF, 0);
				NewOptionItem(STR_ON, 1);
				End();
				SelectOptionItem(GetID(), 0);
			End();
					
			Begin(uiShowPlayerName=NewOption(x, y, STR_DISPLAY_PLAYER_NAME)); y=y+30;
				BeginChild(2);
				NewOptionItem(STR_OFF, 0);
				NewOptionItem(STR_ON, 1);
				End();
				SelectOptionItem(GetID(), 0);
			End();						

		End();

		NewCaption2(STR_SETTINGS);
		NewMsgBar2(BUT_SWITCH_CHANGE_DEFAULT_BACK2);

	End();
	g_settingSelection = SelectOption(uiSettingList, 0);


	Begin(uiSettingLiveMenu=NewUI("SettingLiveMenu"));
		x=190; y=200;
		Begin(uiSettingLiveList=NewUI());
			Begin(NewOption2(x, y, STR_LOGIN_LIVE)); End();
			Begin(NewOption2(x, y, STR_LOGOUT_LIVE)); End(); y=y+30;
			Begin(NewOption2(x, y, STR_FRIENDS_LIST)); y=y+30;
				Begin(NewUI()); Position(230, -2); Size(30,30); Color(1,1,1); End(); 	// notification icon
			End();
			Begin(NewOption2(x, y, STR_PLAYERS_LIST)); y=y+60; End();

			Begin(uiAppearOfflineOption=NewOption2(x, y, STR_APPEAR_OFFLINE)); y=y+30;
				BeginChild(2);
				NewOptionItem2(STR_OFF, 0);
				NewOptionItem2(STR_ON, 1);
				End();
				SelectOptionItem(GetID(), 0);
			End();
			Begin(uiVoiceThroughSpeaker=NewOption2(x, y, STR_VOICE_THROUGH_SPEAKER)); y=y+30;
				BeginChild(2);
				NewOptionItem2(STR_OFF, 0);
				NewOptionItem2(STR_ON, 1);
				End();
				SelectOptionItem(GetID(), 0);
			End();
			Begin(uiVoiceSpeakerVolume=NewOption2(x, y, STR_VOICE_SPEAKER_VOLUME)); y=y+30;
				BeginChild(2);
				for (i=0; i<=10; i++)
					NewOptionItemStr2(NumToStr(i), i*10);
				End();
				SelectOptionItem(GetID(), 10);
			End();
		End();
		NewCaption2(STR_LIVE_SETTINGS);
		NewMsgBar2(BUT_SWITCH_CHANGE_BACK);
		Begin(uiLoginState2=NewUI());
			Position(400, 175);
			Font(1); TextColor(0,0,0); TextSize(22); TextFlag(TEXT_ALIGN_CENTER);
		End();
	End();
	g_settingSelection = SelectOption(uiSettingLiveList, 0);

	Begin(uiComboTable=NewUI("ComboTable"));
		Begin(uiComboList=NewUI());
			for (i=0; i<COMBO_ROW_MAX; i++)
			{
				Begin(NewUI()); Position(400, 200+i*50); Font(1); TextSize(20); TextColor(0,0,0); TextFlag(TEXT_ALIGN_CENTER); End();
				Begin(NewUI()); Position(400, 225+i*50); Font(1); TextSize(20); TextColor(0,0,0); TextFlag(TEXT_ALIGN_CENTER); End();
			}
		End();
		NewCaption2(STR_COMBO_TABLE);
		NewMsgBar2(BUT_SWITCH_BACK2);
		Begin(NewUI());
			Position(400, 170); Font(1); TextSize(25); Text(STR_UP_ARROW); TextColor(1,1,1); TextFlag(TEXT_ALIGN_CENTER);
		End();
		Begin(NewUI());
			Position(400, 455); Font(1); TextSize(25); Text(STR_DOWN_ARROW); TextColor(1,1,1); TextFlag(TEXT_ALIGN_CENTER);
		End();
	End();

	Begin(uiKickMenu=NewUI("KickMenu"));
		Begin(uiKickList=NewUI());
			x=270; y=190;
			for (i=0; i<16; i++)
			{
				Begin(NewSimpleItem(x, y, STR_PLAYERS, 20, 250));
					BeginChild(0); TextFlag(0); TextOffset(40, 2); End();
					BeginChild(1); TextFlag(0); TextOffset(40, 2); End();
				End();
				y = y + 32;
				if (i == 7)
				{
					x = 540;
					y = 190;
				}
			}
		End();

		NewCaption2(STR_KICK_PLAYER);
		NewMsgBar2(BUT_CONFIRM_SWITCH_BACK2);
	End();

	uiConfirmKick = NewDialog("ConfirmKick", -1, BUT_YES_NO);

	Begin(uiAutoDemo=NewUI("AutoDemo"));
		Position(550, 50);
		Begin(NewUI());
			Image("title_small"); Color(1,1,1); Size(200*WIDTH_RATIO, 100);
		End();
	End();
	Begin(uiCredit=NewUI("Credit"));
		Begin(NewUI());
			for (i=0; i<21; i++)
			{
				Begin(NewUI());
					Position(0, i*30);
					Font(1); TextSize(20); TextColor(1,1,1); TextFlag(TEXT_ALIGN_CENTER);
				End();
			}
		End();
		Begin(NewUI());
			Position(0,0); Size(800, 50); Color(0,0,0,1);
		End();
		Begin(NewUI());
			Position(0,550); Size(800, 50); Color(0,0,0,1);
		End();
		Begin(NewUI());
			Position(0,50); Size(800, 50); Gradient(0,0,0,1, 0,0,0,0);
		End();
		Begin(NewUI());
			Position(0, 500); Size(800, 50); Gradient(0,0,0,0, 0,0,0,1);
		End();
	End();


	Begin(uiDedicatedServer=NewUI("DedicatedServer"));
		Begin(NewMsgBar(BUT_DEDICATED_SERVER));
			Position(0, 490);
		End();
	End();

//	uiPong = NewPong();

	Activate(uiRoot, 0);
}

void OnDestroyUI()
{
	DeleteImage(iconDead);
	DeleteImage(iconVIP);
	DeleteImage(iconFriendRequest);
	DeleteImage(iconGameInvite);
}