/* Scenario: RgrAttk1 : "When carnivores attack!"
 * ====================================

NOTE: Make sure that we have 100% DNA dinosaurs before placing dinosaurs!

Problems:
- Hard to get the carnivores to kill the herbivores

Briefing:
"This Park was due to open but the carnivores went berserk.  It must have been something in the food, all of 
a sudden they just went crazy.  The park is now in Emergency Mode.  Please help us win the park back before 
we are due to open..."

o The objectives here are 
	- Retire all 25 "rampaging" carnivores within 10 minutes,
	- Preserve as many of the 40 herbivores as possible

o There are no visitors in the park, just herbivores and carnivores.  

o Mission time limit: 10 minutes

o The carnivores included are:
	- 3 x Tyrannosaurs			(Judith River B)
	- 1 x Spinosaurus			(Chenini) (CUT)
	- 10 x Velociraptors		(Flaming Cliffs)
	- 7 x Carcharadontosaurus	(Chenini)

o The herbivores included are:
	- 5 x Corythosaurus			(Judith River B) 
	- 5 x Ouranosaurus			(Chenini) (CUT)
	- 7 x Homalocephale			(Flaming Cliffs) (CUT)
	- 10 x Gallis               (Flaming Cliffs)

o The structures available:
	- 2 x Ranger Stations [widely spaced in the Park]
	- 1 x Park Entrance
	- Scenic attractions as set dressing.

o Victory Conditions:  All carnivores retired in time-limit.
o Failure Conditions:  All herbivores dead; Player runs out of time.
*/

mission RgrAttk1
{
	;// mission info
	.info "budget" 0
	.info "objectives" 1
	.info "savestate" "RgrAttk1"

	;// systems to activate/de-activate
	.systemactive "Economy"				false
	.systemactive "Mail"				false

	.systemactive "Visitor Pool"		false
	.systemactive "Corporate System"	false
	.systemactive "Build Menu"			false
	.systemactive "Enclosure Analyser"	false
	.systemactive "Weather System"		false

	;// features to disable
	.featuredisable "AParkGuestbookDialog"
	.featuredisable "AParkSafetyDialog"
	.featuredisable "AStructureSummaryDialog"
	.featuredisable "AParkFinanceDialog"
	.featuredisable "ADinoSummaryDialog"
	.featuredisable "GotoParkEntrance"
	.featuredisable "EmergencyOn"
	.featuredisable "GotoSafari"
	.featuredisable "AResearchDialog"
	.featuredisable "Manager"
	.featuredisable "SaveGame"						;// Disable all save game menu
	.featuredisable "LoadGame"						;// Disable all load game menu
	.featuredisable "ParkManager_Dinosaurs"			;// Disable all "dinosaurs" submenu
	.featuredisable "ParkManager_Build"				;// Disable the build menu
	.featuredisable "Command_Orders"				;// Disables ALL "order" commands
	.featuredisable "AutoRescue"					;// Disables automatic rescues
	.featuredisable "BuildParkEntrance"				;// Disable build park entrace from manager

	;// fossil maps to enable
	.fossilsenable "Chenini"
	.fossilsenable "FlamingCliffs"
	.fossilsenable "JudithRiverB"

	.misparam
	.objparam 1 0		;// Number of carnivores left

	;// variable declarations 
	.var iHerbivoreCount
	.var iCarnivoreCount

	;// mission states
	state MissionInit
	{
		action SetWeatherFrequency(0, 100)
		action SetWeatherFrequency(1, 0)
		action SetWeatherFrequency(2, 0)
		action SetWeatherFrequency(3, 0)
		action SetWeatherFrequency(4, 0)

		action SendWeather(0)
		action LockCurrentWeather(true)

		action SetAllSpeciesDinoDNA(100)
		action VaccinateAllDinosaurs()
		action RemoveAllMailMessages()

		;// Put the park into emergency mode
		action SetEmergencyMode(true)

		;// Set up minigame
		action SetCurrentMiniGameParamList(0)		; This is param list AddMiniGameParam() will add Params to

		action AddMiniGameParam("IsScenario", true)

		;// Make it so that the user can't exit the minigame
		action AddMiniGameParam("SetMiniGameExitEnable", false)

		;// **** Allow/Disallow different ranger "modes"
		;// Enable Retire
		action AddMiniGameParam("SetModeEnable", 4, true)

		;// **** Allow/Disallow components
		;// Allow retire of all dinosaurs, but don't count herbivores as targets
		action AddMiniGameParam("SetRetireFlags", 17)

		;// Initialises bullet limitation
		action AddMiniGameParam("InitBulletLimit", 40);

		;// The user can freely enter and leave minigames within the mission.  
		;// Whenever a new minigame is created, it will use this parameter list
		action SetDefaultMiniGameParamList(0)

		;// Start the minigame - RgrAttack(0), Game #1
;//		action StartMiniGame(0, 1)  ;// This is now performed by the PlayTransition call while the screen is black!

		action SetDinoTypeToMissionMode(6)

		transition
		{
			direct goto PlayFlyOver
		}	
	}

	state PlayFlyOver
	{
		transition PlayTransition(0, false, 0)
		{
			goto StartMission
		}
	}

	state StartMission
	{
		transition ShowMissionIntro("facebuttonMuldoon")
		{
			;// Start timer
			action EnableMissionTimer(true)
			action StartMissionTimer(240.0)

			action StartTimer(2, 5)

			goto MiniGameCheck
		}
	}

	;// Check to see if the minigame has been completed
	state MiniGameCheck
	{
		;// Keep carnivores enraged
		action SetDinoStress(4, 1.0)

		iCarnivoreCount = GetDinoTypeCount(4)

		action SetObjectiveParametersFromVars(1, iCarnivoreCount);

		transition iCarnivoreCount == 0
		{
			action SetObjectiveStatus(1, true)
			goto MissionVictory
		}

		transition HasMissionTimerElapsed()
		{
			goto MissionFailureOuttaTime
		}

		iHerbivoreCount = GetDinoTypeCount(5);

;//		action SetObjectiveParametersFromVars(2, iHerbivoreCount);

		transition iHerbivoreCount == 0
		{
			goto MissionFailureHerbDead
		}

		transition HasTimerElapsed(2)
		{
			action StartTimer(2, 20)

			action SetDinoTypeToMissionMode(6)

			goto MiniGameCheck
		}
	}

	;// Success
	state MissionVictory
	{
		action StartTimer(1, 5)

		transition 
		{
			goto MissionVictoryWait
		}
	}

	state MissionVictoryWait
	{
		transition HasTimerElapsed(1)
		{
			goto MissionVictoryShow
		}
	}

	state MissionVictoryShow
	{
		transition ShowMissionVictory("facebuttonMuldoon")
		{
			action SetMissionWon()
			action UnlockMission("RgrMust1")
			action SaveOptions()

			goto SaveOptions
		}
	}

	state SaveOptions
	{
		transition NotCurrentGameState("AOptionsSaveState")
		{
			goto MissionComplete
		}
	}

	;// Mission failed because all the herbivores were killed
	state MissionFailureHerbDead
	{
		transition ShowMissionFailure("facebuttonMuldoon", "Mission_RgrAttk1_Failure_HerbDead")
		{
			goto MissionComplete
		}
	}

	;// Mission failed because the gallis weren't mustered within the given time
	state MissionFailureOuttaTime
	{
		transition ShowMissionFailure("facebuttonMuldoon", "Mission_RgrAttk1_Failure_OuttaTime")
		{
			goto MissionComplete
		}
	}

	;// Go back to the front screen
	final state MissionComplete
	{
	}
}