/* Scenario: Any Port In A Storm
 * ====================================
 *
 */

mission StormIsland
{
	;// mission info
	.info "objectives" 1
	.info "savestate" "StrmIsld"
	.info "budget" 100000

	;// systems to activate/de-activate
	.systemactive "Economy"				true
	.systemactive "Visitor Pool"		true
	.systemactive "Corporate System"	true
	.systemactive "Build Menu"			true
	.systemactive "Enclosure Analyser"	true
	.systemactive "Weather System"		true

	;// features to disable (Example)
	;.featuredisable "AFossilHuntDialog"

	;// fossil maps to enable (Example)
	.fossilsenable "MorrisonB"


	;// mission paramaters
	.misparam 3 3

	;// objective parameters
	.objparam 1 3 3

	;// variable declarations (Example)
	; .var iCounter

	;// mission states
	state MissionInit
	{
		action SetWeatherFrequency(0, 0)
		action SetWeatherFrequency(1, 10)
		action SetWeatherFrequency(2, 75)
		action SetWeatherFrequency(3, 15)
		action SetWeatherFrequency(4, 0)

		;// Make sure first weather is light rain
		action SendWeather(1)

		action SetDinoDNA("camara", 65)

		;// Clear mail out
		action RemoveAllMailMessages()

		transition
		{
			direct goto ShowMissionIntro
		}
	}

	state ShowMissionIntro
	{
		transition ShowMissionIntro()
		{
			action ShowObjectives()
			goto ShowObjectives
		}
	}

	state ShowObjectives
	{
		transition ObjectivesClosed()
		{
			goto CheckObjective
		}
	}

	state CheckObjective
	{
		transition GetParkRating() >= 3.0
		{
			action SetObjectiveStatus(1, true)
			goto MissionVictory
		}

		transition GetElapsedTime(4) > 3.0
		{
			action SetObjectiveStatus(1, false)
			goto MissionFailure
		}
	}

	state MissionVictory
	{
		transition ShowMissionVictory()
		{
			action SetMissionWon()
			action SaveOptions()

			goto SaveOptions
		}
	}

	state SaveOptions
	{
		transition NotCurrentGameState("AOptionsSaveState")
		{
			goto MissionComplete
		}
	}

	state MissionFailure
	{
		transition ShowMissionFailure()
		{
			goto MissionOver
		}
	}

	state MissionComplete
	{
		
	}

	; // Will return to front end
	final state MissionOver
	{
		
	}
}