//Vader B
state Base {
	Conditions {
	}
	Actions {
		SetState "GoToDoorTrigger"
	}
}

state GoToDoorTrigger {
	Conditions {
		if DoorOpen "door_1" == 1 goto Part2

		if ForceComplete "press_1" == 0 and
		if StuckTime > 0 goto SmashPot

		if ForceComplete "press_2" == 0 and
		if StuckTime > 0 goto SmashPot
	}
	Actions {
		CycleCharacter "time=0.5" "Catagory=Jedi"
		GoToDoorTrigger "name" "door_1" "waittime=1"
	}
}

state SmashPot {
	Conditions {
	}
	Actions {
		PressJumpButton
		UseWeapon
		SetState "GoToDoorTrigger"
	}
}

///////////////////Part2
state Part2 {
	Conditions {
		if Message "SteamPuzzleComplete" == 1 goto Part3

		if FreePlay == 1 and
		if PlayerInTriggerArea "tap_2" == 1 goto GoThroughSteam

		if Message "SteamPuzzleComplete" == 0 and 
		if PlayerUsingForce "tap_1" == 1 goto GoToTap2

		if Message "SteamPuzzleComplete" == 0 and 
		if InTriggerArea "tap_2" == 1 goto GoToTap2
	}
	Actions {
		GoToLocator "name" "Wait2"
	}
}

state GoThroughSteam {
	Conditions {
	}
	Actions {
		CycleCharacter "time=0.5" "Catagory=Astromech"
		GoToLocator "name" "tap_2" "0.5"
		SetState "UseTap2"
	}
}

state GoToTap2 {
	Conditions {
		if Message "SteamPuzzleComplete" == 1 goto Part3

		if PlayerUsingForce "tap_1" == 0 and
		if InTriggerArea "tap_2" == 0 goto Part2

		if PlayerInTriggerArea "tap_2" == 1 goto Part3
	}
	Actions {
		GoToLocator "name" "tap_2" "0.5"
		SetState "UseTap2"
	}
}

state UseTap2 {
	Conditions {
		if Message "SteamPuzzleComplete" == 1 goto Part3

		if PlayerUsingForce "tap_1" == 0 and
		if InTriggerArea "tap_2" == 0 goto Part2

		if PlayerInTriggerArea "tap_2" == 1 goto Part3
	}
	Actions {
		UseForce "tap_2"
	}
}

////////////////Part 3
state Part3 {
	Conditions {
	}
	Actions {
		SetState "UseCell2"
	}
}

state UseCell1 {
	Conditions {
		if ObstacleChainPhase "arm_puzzle" > 1 goto Part4
		if PlayerUsingForce "cell_1" == 1 goto UseCell2

		if BeenHit == 1 goto Part3_Idle
	}
	Actions {
		GoToLocator "name" "cell" "0.5"
		UseForce "cell_1"
	}
}

state UseCell2 {
	Conditions {
		if ObstacleChainPhase "arm_puzzle" > 1 goto Part4
		if PlayerUsingForce "cell_2" == 1 goto UseCell1

		if BeenHit == 1 goto Part3_Idle
	}
	Actions {
		GoToLocator "name" "cell" "0.5"
		UseForce "cell_2"
	}
}

state Part3_Idle {
	Conditions {
	}
	Actions {
		FacePlayer "1"
		SetState "Part3"
	}
}

state Part4 {
	Conditions {
	}
	Actions {
		GoToLocator "name" "end2"
	}
}