//BlockadeRunner_C

state InActive {
	Conditions {
		if FreePlay == 1 goto Activate
		
		if IAm "PrincessLeia" == 1 and
		if Message "R2D2_Active" == 0 goto Activate
		
		if IAm "PrincessLeia" == 0 goto Activate
	}
	Actions {
	}
}

state Activate {
	Conditions {
	}
	Actions {
		Activate	;Activate starts the creature. Will be started at position calculated in AllocatedPickup
	}
}

state Base {
	Conditions {
		if FreePlay == 1 goto NormalUpdate

		if IAm "C3PO" == 1 and 
		if Message "C3PO_Active" == 0 goto C3PO_Wait

		if IAm "R2D2" == 1 and 
		if Message "R2D2_Active" == 0 goto R2D2_Wait
		
		if IAm "RebelFriend" == 1 and
		if Message "RebelFriendInParty" == 0 goto RebelFriend_Init

		if FreePlay == 0 goto NormalUpdate
	}
	Actions {	
	}
}

state NormalUpdate {
	ReferenceScript {
		Script=GeneralParty
		Source=Global
		ReturnState=NormalUpdate
		Conditions {
		}
	}
	Conditions {
		if FreePlay == 0 and
		if IAm "C3PO" == 1 and 
		if EitherPlayerInTriggerArea "Grabber" == 1 goto GoToC3PO_Door
	}
	Actions {	
		FollowPlayer "1"
	}
}

state GoToC3PO_Door {
	Conditions {
		if EitherPlayerInTriggerArea "Grabber" == 0 goto NormalUpdate
	}
	Actions {
		GoToLocator "name" "C3PO_Door"
	}
}

state C3PO_Wait {
	Conditions {
	}
	Actions {
		CannotDropIn
		NotWithParty
		SnapToLocator "name=C3PO"	
	}
}

state R2D2_Wait {
	Conditions {
	}
	Actions {
		CannotDropIn 
		NotWithParty
		SnapToLocator "name=R2D2"	
	}
}

state RebelFriend_Init {
	Conditions {
	}
	Actions {
		SetTaggable "FALSE"
		CannotDropIn
		NotWithParty
		SnapToLocator "name=RebelFriend"	
		SetState "RebelFriend_Update"
	}
}

state RebelFriend_JoinParty {
	Conditions {
	}
	Actions {
		SetTaggable
		CannotDropIn "FALSE"
		NotWithParty "FALSE"
		SetState "NormalUpdate"
	}
}

state RebelFriend_Update {
	ReferenceScript {
		Script=lift_rebel
		Source=Level
		ReturnState=RebelFriend_Update
		Conditions {
		}
	}
	Conditions {
		if Message "RebelFriendInParty" == 1 goto RebelFriend_JoinParty
	}
	Actions {
	}
}