//BlockadeRunner_C
state InActive {
	Conditions {
		if ObstacleAtStart "lift_lever" == 1 and
		if FreePlay == 1 goto Activate
	}
	Actions {
	}
}

state Activate {
	Conditions {
	}
	Actions {
		Activate	;Activate starts the creature. Will be started at position calculated in AllocatedPickup
	}
}

state Base {
	Conditions {
		if FreePlay == 1 goto FreePlay_Start
		if Message "RebelFriendInParty" == 0 goto StaticFight
	}
	Actions {	
	}
}

state FreePlay_Start {
	Conditions {
	}
	Actions {	
		Respawnable
		SetState "StaticFight"
	}
}

====================Phase 1===================
state StartPhase1 {
	Conditions {
	}
	Actions {	
		//GetLocatorFromGroup "name=GoodyPhase1"
		SetLocator "name=GoodyPhase1"
		SetState "StaticFight"
	}
}

====================Phase 2===================
state StartPhase2 {
	Conditions {
	}
	Actions {	
		//GetLocatorFromGroup "name=GoodyPhase2"
		SetLocator "name=GoodyPhase2"
		SetState "StaticFight"
	}
}

====================Phase 3===================
state StartPhase3 {
	Conditions {
	}
	Actions {	
		//GetLocatorFromGroup "name=GoodyPhase3"
		SetLocator "name=GoodyPhase3"
		SetState "StaticFight"
	}
}

=======================================
state StaticFight {
	Conditions {
		if Timer > 1 and
		if IsSetAlive "1" == 0 goto TroopersGone
		
		if GotLocator == 1 and
		if LocatorRange > 0.25 goto StaticFight
		
		if GotLocator == 0 and
		if Message "PhaseC" > 0 goto StartPhase1
		
		if CurrentLocatorIs "GoodyPhase1" == 1 and
		if Message "PhaseC" > 1 goto StartPhase2
		
		if CurrentLocatorIs "GoodyPhase2" == 1 and
		if Message "PhaseC" > 2 goto StartPhase3
	}
	Actions {	
		GoToLocator
		EngageOpponent "static" "firerange 99"
	}
}

=======================================
state TroopersGone {
	Conditions {
		if ObstacleAtStart "lift_lever" == 1 goto PullLever
	}
	Actions {
		GoToOrigin "walk"
	}
}

state PullLever {
	Conditions {
		if ObstacleAtStart "lift_lever" == 0 goto FinishedPullingLever
	}
	Actions {
		DontPush 
		;CameraCut "campos_x=17.1" "campos_y=2.0" "campos_z=2.76" "tgt_character=RebelScum1" "FollowTgt" "blend_in_time=0.0" "end_time=infinite" "no_borders"
		PullLever "name=lift_lever"
	}
}

state FinishedPullingLever {
	Conditions {
	}
	Actions {
		DontPush "FALSE"
		;CameraCut "campos_x=17.1" "campos_y=2.0" "campos_z=2.76" "tgt_character=RebelScum1" "FollowTgt" "blend_in_time=0.0" "end_time=0.5" "no_borders"
		SetMessage "name=RebelFriendInParty" "value=1"
		SetState "Base"
	}
}