/****************************************************************************
* CS_FortIntro.SNL
* Cutscene showing the kewlett Fort
* TimS Jan 20 2003
****************************************************************************/

VAR g_MaceObject;

/****************************************************************************
* Called when the Cutscene is first created
****************************************************************************/
OnCreate()
{
    g_MaceObject = CS_ClonePlayer();
    FX_PlayAnimation( g_MaceObject, "GAMEDATA_TAN_EDGEIDLEB", 0.15, "", 1.0 );

    DEBUG( "Beginning cutscene.." );
    CS_ShowPlayers( 0 );
    CS_SetBorderAlpha( 1.0 );
    CS_MoveToCamera( "CamFort01", 0.0, "" );
    CS_MoveToCamera( "CamFort1B", 13.0, "OnReachCamFort1B" );
    CS_FadeIn( 2.0 );
    CS_AddTimer( 3.0, "OnIntroText" );
    CS_SetDepthOfField( 0.0, 5000.0,  1000.0 );
    CS_SetDepthOfField( 10.0, 500.0,  1000.0 );
    CS_SetDepthOfFieldTarget( "KFTurret0", 100, 700.0 );
}
/***************************************************************************/

OnIntroText()
{
    CS_ClearText();
    CS_SetText( 0, "Eww, this is gonna be tough to breach, so" );
    CS_SetText( 1, "it's up to you." );
}

OnReachCamFort1B()
{
    CS_MoveToCamera( "CamFort02", 0.0, "" );
    CS_MoveToCamera( "CamFort2B", 6.0, "OnReachCamFort2B" );
    CS_AddTimer( 5.0, "OnFort2BFadeOut" );
    CS_SetDepthOfFieldTarget( "KBFrame0", 0, 500.0 );
    CS_ClearText();
    CS_SetText( 0, "You can just smash through the front door, or look" );
    CS_SetText( 1, "for another way in." );
}

OnFort2BFadeOut()
{
	CS_FadeOut( 1.0 );
}

OnReachCamFort2B()
{
	CS_FadeIn( 1.0 );
    CS_MoveToCamera( "CamFort03", 0.0, "" );
    CS_AddTimer( 3.0, "OnHoldOnCamFort03" );
    CS_SetDepthOfFieldTarget( "KFTurret1", 0, 500.0 );

    CS_ClearText();
    CS_SetText( 0, "The cannons?" );
    CS_AddTimer( 5.5, "Fort2B_Text" );
}

Fort2B_Text()
{
    CS_ClearText();
    CS_SetText( 0, "I'll bet those power lines lead to whatever is giving" );
    CS_SetText( 1, "them juice." );
}

OnHoldOnCamFort03()
{
    CS_MoveToCamera( "CamFort04", 5.0, "OnReachCamFort04" );
}

OnReachCamFort04()
{
    CS_MoveToCamera( "CamFort05", 4.0, "OnReachCamFort05" );
}

OnReachCamFort05()
{
    CS_MoveToCamera( "CamFort06", 2.5, "OnReachCamFort06" );
}

OnReachCamFort06()
{
    CS_FadeOut( 2.0 );
    CS_AddTimer( 2.0, "EndCutScene" );
}


EndCutScene()
{
    HUD_AddMessage( 10.0, "Disable or Destroy the Fort's Turrets" );

    DeleteObject( g_MaceObject );
    CS_ShowPlayers( 1 );
    CS_End();
}