//========================================================================================================================
// AidaPostM01.u2s
// AI script for Aida before Hell
//========================================================================================================================
:ScriptStart

//debugmode 1
inert 1
call TriggeredActions

//========================================================================================================================
// Briefing
//========================================================================================================================

// Waiting for player to show up for briefing
//------------------------------------------------------------------------------------------------------------------------
:BriefingStandby
handlergroup
ontrigger dlgStartBriefing gotolabel StartBriefing 
ontrigger dlgDontStartBriefing gotolabel BriefingStandby 
ontrigger DialogAbortEnd gotolabel BriefingStandby
handlergroupend
dialogenable AidaPostM01BriefingStandby										// ### enable topic ###

:BriefingStandbyLoop
gotoactor PathNode10														// *** scripted actions ***
directionalpatrol 1
gotoactor PatrolPoint4														// right side keyboard
directionalpatrol 0
testpropertyg ResizableStaticMesh34 DrawScale 0 gotolabel BriefingStandby1	// worktable command prompt up?
sendevent ScannerStatusScreen 0												// opening command prompt...
:BriefingStandby1	
agentcall TypeFlatLong 1													
sleep 1.5
gotoactor PathNode9															// walking to other side of scanner...
directionalpatrol 1
gotoactor PatrolPoint0
directionalpatrol 0
//agentcall TypeFlat0Short 1
agentcall TypeFarLong 1
turntoactor Mover21

testpropertyg ResizableStaticMesh11 DrawScale 0 gotolabel BriefingStandby2	// scanned pictures up?
sendevent ScannerPopup01 0
sendevent ScannerSequence 0
:BriefingStandby2
sleep 3.5

directionalpatrol 1															// walking in front of scanner...
gotoactor PatrolPoint23
directionalpatrol 0

sendevent ScannerPopup02 0
sendevent ScannerSequence 0
//headtracking 0
sleep 1.5
setsatellite Sat_Headtrack ResizableStaticMesh11								// watching pictures as they pop up...
sleep 3.5

sendevent ScannerPopup03 0
sendevent ScannerSequence 0

setsatellite Sat_Headtrack ResizableStaticMesh22
sleep 3.5
setsatellite Sat_Headtrack ResizableStaticMesh23
sleep 3
setsatellite Sat_Headtrack Pawn
//headtracking 1

gotoactor PathNode10														// walking back to right side...
directionalpatrol 1
gotoactor PatrolPoint4
directionalpatrol 0
sendevent ScannerPopup01 0
sendevent ScannerPopup02 0
sendevent ScannerPopup03 0
agentcall TypeFlatLong 1													// shutting down command prompt
sendevent ScannerStatusScreen 0
sleep 2
gotoactor PathNode100
directionalpatrol 1
gotoactor PathNode2
directionalpatrol 0
sleep 8
sleeprand 10
gotolabel BriefingStandbyLoop												// *** end scripted actions ***

// Making sure everything's back to normal
//------------------------------------------------------------------------------------------------------------------------
:BriefingWTShutdown
call DisableAllTopics
dialogenable AidaPostM01WTShutdownNotNow
sleep 0.1																		// make sure that shutting down headlook will work
headtracking 1
setsatellite Sat_Headtrack Pawn
testpropertyg ResizableStaticMesh34 DrawScale 0 call BriefingWTShutdown01		// worktable command prompt up?
return

:BriefingWTShutdown01
directionalpatrol 1
gotoactor PatrolPoint4															// right side keyboard
directionalpatrol 0
agentcall TypeFlat0Short 1
sendevent ScannerStatusScreen 0
testpropertye ResizableStaticMesh11 DrawScale 0 gotolabel BriefingWTShutdown02	// scanned pictures up?
sendevent ScannedScreen01 0
:BriefingWTShutdown02
testpropertye ResizableStaticMesh22 DrawScale 0 gotolabel BriefingWTShutdown03
sendevent ScannedScreen02 0
:BriefingWTShutdown03
testpropertye ResizableStaticMesh23 DrawScale 0 gotolabel BriefingWTShutdown04
sendevent ScannedScreen03 0
:BriefingWTShutdown04
return


// Briefing Console
//------------------------------------------------------------------------------------------------------------------------
:StartBriefing
//sendevent BriefingRoomDoorTrigger 0									// lock door -> .dlg
sendevent RaiseDropshipDispatcher 1										// make dropship to next mission available
sendevent u2sEnableHellStartTrigger 0
call BriefingWTShutdown
call BriefingActions

:StartHolograph
gotoactor PathNode111
directionalpatrol 1
gotoactor PatrolPoint12													// holograph control
directionalpatrol 0
agentcall TypeFlat0Short 1
sendevent StartHoloTableSequenceDispatcher 0 
sendevent PostM01SurfaceOnDispatcher 0
sleep 0.5
dialogenable AidaPostM01BriefingTalk									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk							// *** Hell is an Axon Corporation research facility that works closely with the TCA, the organization we are all so proud to work for. ***
agentcall TypeFlatLong 1
sleep

:HolographStage01
sleep .2
call DisableAllTopics
dialogenable AidaPostM01BriefingTalk2									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk2							// *** As you can see the base has four research modules located around the the central hub. ***
sleep 0.5
agentcall TypeFlat0Short 1
sendevent PostM01ToggleBase01Dispatcher 0
sleep

:HolographStage02
agentcall TypeFlat0Short 1
sendevent PostM01Terrain01 0											// terrain shrink
call DisableAllTopics
dialogenable AidaPostM01BriefingTalk3									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk3							// *** I got some archive images of the base here. ***
agentcall TypeFlat0Short 1
sendevent PostM01ProjectorOnDispatcher 0
sendevent PostM01ToggleBigBaseImage 0
sleep

:HolographStage03
agentcall TypeFlat0Short 1
call DisableAllTopics
dialogenable AidaPostM01BriefingTalk4									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk4							// *** Here's another one. ***
agentcall TypeFlat0Short 1
sendevent PostM01ToggleBigBaseImage 0
sendevent PostM01ToggleBigBaseImage02 0
sleep

:HolographStage04
turntoactor StaticMeshActor103
agentcall TypeFlat0Short 1
sendevent PostM01ToggleBigBaseImage02 0
sendevent PostM01ProjectorOffDispatcher 0
sendevent PostM01Terrain01 0
agentcall TypeFlatLong 1
sendevent PostM01BaseOnDispatcher 0
call DisableAllTopics
dialogenable AidaPostM01BriefingTalk5									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk5							// *** We will set you down close to one of the research modules. Here's a closeup of the terrain surrounding the entrance. ***
sleep

:HolographStage05
agentcall TypeFlat0Short 1
sendevent PostM01ToggleArrow 0
call DisableAllTopics
dialogenable AidaPostM01BriefingTalk6									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk6							// *** The dropship will land right here. ***
sleep

:HolographStage06
sleep 0.2
call DisableAllTopics
dialogenable AidaPostM01BriefingTalk7									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk7							// *** You can take the bridge that will lead you right into the base. ***
sleep 0.1
agentcall TypeFlat0Short 1
sendevent PostM01ToggleArrow 0
sendevent PostM01ToggleBridge 0
sleep

:HolographStage07
agentcall TypeFlatLong 1
sendevent PostM01ToggleBridge 0
sendevent PostM01BaseOffDispatcher 0
sleep 0.5
sendevent EndHoloTableSequenceDispatcher 0
call DisableAllTopics
dialogenable AidaPostM01BriefingTalk8									// ### enable topic ###
dialoginitiate Player AidaPostM01BriefingTalk8							// *** Good luck down there! ***
sleep

:HolographStage08
sendevent BriefingRoomDoorTrigger 0										// unlock door
gotolabel AfterBriefing

// Briefing events (called)
//------------------------------------------------------------------------------------------------------------------------
:BriefingActions
sleep 0.5
ontrigger dlgPostM01HolographStage01 gotolabel HolographStage01 1
ontrigger dlgPostM01HolographStage02 gotolabel HolographStage02 1
ontrigger dlgPostM01HolographStage03 gotolabel HolographStage03 1
ontrigger dlgPostM01HolographStage04 gotolabel HolographStage04 1
ontrigger dlgPostM01HolographStage05 gotolabel HolographStage05 1
ontrigger dlgPostM01HolographStage06 gotolabel HolographStage06 1
ontrigger dlgPostM01HolographStage07 gotolabel HolographStage07 1
ontrigger dlgPostM01HolographStage08 gotolabel HolographStage08 1
return

//========================================================================================================================
// After briefing
//========================================================================================================================
:AfterBriefing
call DisableAllTopics
dialogenable AidaPostM01AfterBriefing									// ### enable topic ###
dialogenable PostM01HoloControls
gotoactor PathNode5
directionalpatrol 1
gotoactor PatrolPoint3
directionalpatrol 0
turntoactor ZoneInfo0

:AfterBriefingLoop
sleep

//========================================================================================================================
// Global calls
//========================================================================================================================

// global events/calls
//------------------------------------------------------------------------------------------------------------------------
:TriggeredActions
return

:DisableAllTopics
ontrigger DialogAbortEnd
dialogdisable AidaPostM01BriefingStandby
dialogdisable AidaPostM01AfterBriefing
dialogdisable AidaPostM01NotNow
return

:ScriptEnd