//========================================================================================================================
// AidaPostM07.u2s
// AI script for Aida between Waterfront and Obolus
//========================================================================================================================
:ScriptStart

inert 0
sendevent BriefingRoomDoorTrigger 0										// unlock door
call TriggeredActions
sleep

//========================================================================================================================
// Briefing
//========================================================================================================================

// Waiting for player to show up for briefing
//------------------------------------------------------------------------------------------------------------------------
:BriefingStandby
gotoactor PathNode12
turntoactor PathNode1
call DisableAllTopics
dialogenable AidaPostM07BriefingStartCheck									// ### enable topic ###
handlergroup
ontrigger dlgStartBriefing gotolabel StartBriefing 
ontrigger dlgDontStartBriefing gotolabel BriefingStandby 
ontrigger DialogAbortEnd gotolabel BriefingStandby
handlergroupend
sleep

:TalkToPlayer
call DisableAllTopics
dialogenable AidaPostM07SmallTalk											// ### enable topic ###
handlergroup
//ontrigger dlgStartBriefing gotolabel StartBriefing 
//ontrigger dlgDontStartBriefing gotolabel BriefingStandby 
ontrigger DialogEnd gotolabel StandAroundAndDontDoBriefingBecauseWeDontHaveDialog 
ontrigger DialogAbortEnd gotolabel StandAroundAndDontDoBriefingBecauseWeDontHaveDialog
handlergroupend
gotoactor Player 64
dialoginitiate Player AidaPostM07SmallTalk
sleep

:StandAroundAndDontDoBriefingBecauseWeDontHaveDialog
dialogenable AidaPostM07NotNow
sendevent BriefingRoomDoorTrigger 0										// unlock door
sendevent RaiseDropshipDispatcher 0										// make dropship to next mission available
sendevent u2sEnableNaKojaStartTrigger 0
gotoactor PathNode9
turntoactor Player
sleep

// Briefing Console
//------------------------------------------------------------------------------------------------------------------------
:StartBriefing
sendevent BriefingRoomDoorTrigger 0										// lock door
sendevent RaiseDropshipDispatcher 0										// make dropship to next mission available
sendevent u2sEnableNaKojaStartTrigger 0
call BriefingActions

:StartHolograph
call DisableAllTopics
gotoactor PathNode100
directionalpatrol 1
gotoactor PatrolPoint2													// holograph control
directionalpatrol 0
agentcall TypeFlatLong 1
sendevent StartHoloTableSequenceDispatcher 0 
sendevent PostM07SurfaceOnDispatcher 0
agentcall TypeFlat0Short 1
dialogenable AidaPostM07BriefingTalk									// ### enable topic ###
dialoginitiate Player AidaPostM07BriefingTalk							// *** Okay, let's take a look at the base and surrounding terrain. ***
sleep

:HolographStage01
sleep 0.2
call DisableAllTopics
dialogenable AidaPostM07BriefingTalk2									// ### enable topic ###
dialoginitiate Player AidaPostM07BriefingTalk2							// *** We will drop you off all the way over here... ***
agentcall TypeFlat0Short 1
sendevent PostM07ToggleArrow01 0
sleep 2
agentcall TypeFlat0Short 1
sendevent PostM07ToggleArrow02 0
sleep 3

:HolographStage02
sleep 0.2
call DisableAllTopics
dialogenable AidaPostM07BriefingTalk3									// ### enable topic ###
dialoginitiate Player AidaPostM07BriefingTalk3							// *** Here's a closeup of the base structure. ***
agentcall TypeFlat0Short 1
sendevent PostM07ToggleArrow01 0
sendevent PostM07ToggleArrow02 0
sendevent PostM07SurfaceOffDispatcher 0
sendevent PostM07BaseOnDispatcher 0
sleep

:HolographStage03
sleep 0.2
call DisableAllTopics
dialogenable AidaPostM07BriefingTalk4									// ### enable topic ###
dialoginitiate Player AidaPostM07BriefingTalk4							// *** The main entrance to the base is here. ***
agentcall TypeFlat0Short 1
sendevent PostM07ToggleEntrance 0
sleep

:HolographStage04
agentcall TypeFlat0Short 1
sendevent PostM07ToggleEntrance 0
sendevent PostM07ToggleGates 0
call DisableAllTopics
dialogenable AidaPostM07BriefingTalk5									// ### enable topic ###
dialoginitiate Player AidaPostM07BriefingTalk5							// *** Defensive mechanisms like these shieldwalls have been installed... ***
sleep

:HolographStage05
agentcall TypeFlat0Short 1
sendevent PostM07ToggleGates 0
sendevent PostM07ToggleBridge 0
call DisableAllTopics
dialogenable AidaPostM07BriefingTalk6									// ### enable topic ###
dialoginitiate Player AidaPostM07BriefingTalk6							// *** Regardless of how you make it in, once you're inside the base you'll be on your own. ***
sleep

:HolographStage06
agentcall TypeFlat0Short 1
sendevent PostM07ToggleBridge 0
sendevent PostM07BaseOffDispatcher 0
sendevent EndHoloTableSequenceDispatcher 0
sendevent BriefingRoomDoorTrigger 0										// unlock door
call DisableAllTopics
dialogenable AidaPostM07BriefingTalk7									// ### enable topic ###
dialoginitiate Player AidaPostM07BriefingTalk7							// *** Good luck! ***
sleep 0.1
directionalpatrol 1
gotoactor PatrolPoint20
directionalpatrol 0
gotolabel AfterBriefing


// Briefing events (called)
//------------------------------------------------------------------------------------------------------------------------
:BriefingActions
sleep 0.5
ontrigger dlgPostM07HolographStage01 gotolabel HolographStage01 1
ontrigger dlgPostM07HolographStage03 gotolabel HolographStage03 1
ontrigger dlgPostM07HolographStage04 gotolabel HolographStage04 1
ontrigger dlgPostM07HolographStage05 gotolabel HolographStage05 1
ontrigger dlgPostM07HolographStage06 gotolabel HolographStage06 1
return

//========================================================================================================================
// After briefing
//========================================================================================================================
:AfterBriefing
call DisableAllTopics
dialogenable AidaPostM07AfterBriefing									// ### enable topic ###
dialogenable PostM07HoloControls
gotoactor PathNode5
directionalpatrol 1
gotoactor PatrolPoint3
directionalpatrol 0
turntoactor ZoneInfo0
sleep

//========================================================================================================================
// Global calls
//========================================================================================================================

// global events/calls
//------------------------------------------------------------------------------------------------------------------------
:TriggeredActions
ontrigger PostM07CutsceneOver02 gotolabel TalkToPlayer 1
return

:DisableAllTopics
ontrigger DialogAbortEnd
dialogdisable AidaPostM07BriefingStartCheck
dialogdisable AidaPostM07AfterBriefing
return

:ScriptEnd