//========================================================================================================================
// NebanPostM04.u2s
// AI script for Ne'ban between Waterfront and Obolus
//========================================================================================================================
:ScriptStart

//debugmode 11
inert 1
setmovespeed 0.2
ontrigger NebanPostM04StartDialog gotolabel CutsceneStage6 1
ontrigger NebanPostM04InitiateBriefing gotolabel BriefingStandby
sleep

:CutsceneStage6
dialogenable CutscenePostM04Talk3
dialoginitiate Marshal CutscenePostM04Talk3
sleep

//========================================================================================================================
// Briefing
//========================================================================================================================
:BriefingStandby
handlergroup
ontrigger dlgStartBriefing gotolabel StartBriefing
ontrigger dlgDontStartBriefing gotolabel BriefingStandby2
ontrigger DialogAbortEnd gotolabel BriefingStandby2
handlergroupend
sleep 1
dialogenable NebanPostM04BriefingStandby								// ### enable topic ###
dialoginitiate Player NebanPostM04BriefingStandby
sleep

:BriefingStandby2
handlergroup
ontrigger dlgStartBriefing gotolabel StartBriefing
ontrigger dlgDontStartBriefing gotolabel BriefingStandby2
ontrigger DialogAbortEnd gotolabel BriefingStandby2
handlergroupend
sleep

// Briefing Console
//------------------------------------------------------------------------------------------------------------------------
:StartBriefing
sendevent BriefingRoomDoorTrigger 0										// lock door
call BriefingActions

:StartHolograph
call DisableAllTopics
dialogenable NebanPostM04BriefingTalk									// ### enable topic ###
dialoginitiate Player NebanPostM04BriefingTalk							// *** The seagoat has damaged our inertial control systems. ***
sleep

:HolographStage01
call DisableAllTopics
directionalpatrol 1
gotoactor PatrolPoint24
directionalpatrol 0
agentcall Event_A_Type 1
sendevent PostM04WackyTerrain 0
sendevent PostM04WackyTerrainAlarmTrigger 0
sleep 1.5
dialogenable NebanPostM04BriefingTalk2									// ### enable topic ###
dialoginitiate Player NebanPostM04BriefingTalk2							// *** Oh dears!  To be continuation: ***
sleep

:HolographStage02
call DisableAllTopics
turntoactor SpecialEvent12
agentcall Event_A_Type 1
sendevent PostM04WackyTerrain 0
sendevent PostM04WackyTerrainAlarmTrigger 0
sendevent PostM04ProjectorOnDispatcher 0
sleep 1.5
dialogenable NebanPostM04BriefingTalk3									// ### enable topic ###
dialoginitiate Player NebanPostM04BriefingTalk3							// *** Cow patties!  We will set down behind a shield wall. ***
sleep

:HolographStage03
call DisableAllTopics
turntoactor SpecialEvent12
agentcall Event_A_Type 1
sendevent PostM04ProjectorOnDispatcher 0
sendevent PostM04HoloWeirdnessDispatcher 0
sleep 1.5
dialogenable NebanPostM04BriefingTalk4									// ### enable topic ###
dialoginitiate Player NebanPostM04BriefingTalk4							// *** Intercourse!  It will be up to you to hold them off long enough for Isaak to fix the ship. ***
sleep

:HolographStage04
turntoactor SpecialEvent12
agentcall Event_A_Type 1
sendevent EndHoloTableSequenceDispatcher 0
gotolabel AfterBriefing

// Briefing events (called)
//------------------------------------------------------------------------------------------------------------------------
:BriefingActions
sleep 0.5
ontrigger dlgPostM04HolographStage01 gotolabel HolographStage01 1
ontrigger dlgPostM04HolographStage02 gotolabel HolographStage02 1
ontrigger dlgPostM04HolographStage03 gotolabel HolographStage03 1
ontrigger dlgPostM04HolographStage04 gotolabel HolographStage04 1
return

//========================================================================================================================
// After briefing
//========================================================================================================================
:AfterBriefing
sendevent ExitPlatform 0
sendevent StartObolusTrigger 0
sendevent BriefingRoomDoorTrigger 0
dialogenable PostM04HoloDialog
call DisableAllTopics
dialogenable NebanPostM04NotNow									// ### enable topic ###
directionalpatrol 1
gotoactor PathNode8
directionalpatrol 0
sleep

:DisableAllTopics
ontrigger DialogAbortEnd
dialogdisable NebanPostM04BriefingStandby
dialogdisable NebanPostM04NotNow
return

:ScriptEnd