//=============================================================================
// AidaPreSulferon.u2s
// AI script for Aida on Atlantis between MXX and Sulferon (PreSulferon)
//=============================================================================

inert 0
call TriggeredActions

:Idle 
message "Aida: Idle"
animloop Breathe 1.0 0.0 1
sleep 2
gotolabel Idle


// Debriefing 
//------------------------------------------------------------------------------------------------------------------------
:GoToDroparea
message "Aida: GoToDroparea"
directionalpatrol 1
setmovespeed 0.6
gotoactor PathNode22
dialoginitiate Player SulferonDebriefingStandby
ontrigger dlgPreSulferonAidaGoToDebriefing gotolabel GoToDebriefing   // walk to briefing room to do debriefing
ontrigger dlgPreSulferonAidaGoToHoloroomAlternate gotolabel GoToHoloroomAlternate
sleep

:GoToDebriefing
message "Aida: GoToDebriefing"
directionalpatrol 1
setmovespeed 0.6
gotoactor PathNode5
sendevent u2sPreSulferonAidaDebriefingStartTrigger 0   //enable trigger

:DebriefingStandby
message "Aida: DebriefingStandby"
ontrigger PreSulferonAidaDebriefingStart gotolabel Debriefing
animloop console_idle
sleep

:Debriefing
sendevent u2sPreSulferonAidaDebriefingStartTrigger 0   // disable trigger
//:DebriefingLoop // make sure we don't toggle trigger
message "Aida: Debriefing"
ontrigger dlgPreSulferonAidaDebriefingEnd gotolabel GoToHoloroom
animloop Breathe 1.0 0.0 1
dialoginitiate Player SulferonDebriefing
sleep


// Intermediate actions: Aida working on a new training simulation (= DM level) in the holoroom 
//------------------------------------------------------------------------------------------------------------------------
:GoToHoloroom
message "Aida: GoToHoloroom"
directionalpatrol 1
animloop WalkLookFrwd 1.0 0.0 1
gotoactor PathNode29
sendevent u2sPreSulferonAidaHoloroomTalkTrigger 0   // enable trigger

:HoloroomLoop
ontrigger PreSulferonAidaHoloroomTalk gotolabel HoloroomTalk
message "Aida: Holoroom loop"
gotoactor PathNode88
animloop Breathe 1.0 0.0 1
sleep 3
gotoactor PathNode29
animloop Breathe 1.0 0.0 1
sleep 3
gotolabel HoloroomLoop

:HoloroomTalk
sendevent u2sPreSulferonAidaHoloroomTalkTrigger 0   // disable trigger
ontrigger dlgPreSulferonAidaHoloroomTalkEnd gotolabel HoloroomLoop
message "Aida: HoloroomTalk"
animloop Breathe 1.0 0.0 1
dialoginitiate Player SulferonHoloroomTalk
sleep


// Alternate path - player has asked to delay debriefing
//------------------------------------------------------------------------------------------------------------------------
:GoToHoloroomAlternate
message "Aida: GoToHoloroomAlternate"
directionalpatrol 1
animloop WalkLookFrwd 1.0 0.0 1
gotoactor PathNode29
sendevent u2sPreSulferonAidaDelayedDebriefingTrigger 0 // enable trigger

:HoloroomLoopAlternate
message "Aida: Holoroom loop alternate"
ontrigger PreSulferonAidaDelayedDebriefing gotolabel DelayedDebriefingTalk
gotoactor PathNode88
animloop Breathe 1.0 0.0 1
sleep 3
gotoactor PathNode29
animloop Breathe 1.0 0.0 1
sleep 3
gotolabel HoloroomLoopAlternate

:DelayedDebriefingTalk
message "Aida: DelayedDebriefingTalk"
sendevent u2sPreSulferonAidaDelayedDebriefingTrigger 0 // disable trigger
ontrigger dlgPreSulferonAidaDelayedDebriefingTalkEnd gotolabel HoloroomLoop
animloop Breathe 1.0 0.0 1
dialoginitiate Player SulferonDelayedDebriefingTalk
sleep 


// Briefing 
//------------------------------------------------------------------------------------------------------------------------
:GoToBriefing   
message "Aida: GoToBriefing"
inert 1
gotoactor PathNode29   // !! add fallback - if she hasn't reached briefing room in x amount of time teleport her there

:BriefingStandbyLoop 
event u2sPreSulferonAidaStartBriefingTrigger 0   // enable trigger
:BriefingStandby 
message "Aida: BriefingStandby"
ontrigger PreSulferonAidaStartBriefing gotolabel StartBriefing 
inert 0
directionalpatrol 1
gotoactor PathNode9 
sleep 3
gotoactor PathNode7
sleep 3
gotolabel BriefingStandby

:StartBriefing
event u2sPreSulferonAidaStartBriefingTrigger 0   // disable trigger
dialoginitiate Player SulferonBriefingStandby
ontrigger dlgSulferonAidaDoStartBriefing gotolabel WalkToConsole 
ontrigger dlgSulferonAidaDontStartBriefing gotolabel BriefingStandbyLoop 
sleep

:WalkToConsole
ontrigger dlgSulferonAidaWalkToHolotable gotolabel WalkToHolotable
directionalpatrol 1
setmovespeed .2
dialoginitiate Player SulferonBriefingStart
gotoactor PathNode5
sleep

:WalkToHolotable
ontrigger dlgSulferonAidaGoToBridge gotolabel WalkToBridge
directionalpatrol 1
setmovespeed .2
gotoactor PathNode6
sleep

:WalkToBridge
directionalpatrol 1
gotoactor PathNode72
sleep

:TestingThis
message "test"
gotolabel Idle

// global reaction to incoming events
//------------------------------------------------------------------------------------------------------------------------
:TriggeredActions
ontrigger PreSulferonDropshipLowered gotolabel GoToDroparea   // triggered after dropship has been lowered
ontrigger AidaOnUse gotolabel TestingThis
return